blob: e1d68afa259bfffbb520bab23d7c117a4ca7d45f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
|
# Maintainer: Frederik Schwan <frederik dot schwan at linux dot com>
pkgname=latex-tuda-ci
pkgver=2.08
pkgrel=1
pkgdesc='TUDa-CI for LaTeX from Technische Universität Darmstadt'
arch=('any')
url='https://github.com/tudace/tuda_latex_templates'
license=('custom')
depends=('latex-tuda-ci-logos')
makedepends=('texlive-core' 'texlive-bin' 'texlive-publishers' 'texlive-latexextra' 'texlive-fontsextra'
'texlive-bibtexextra' 'texlive-pictures' 'biber' 'zip')
replaces=('latex-tuddesign' 'latex-tuddesign-thesis' 'latex-tuddesign-fonts')
source=("https://github.com/tudace/tuda_latex_templates/archive/v${pkgver}.tar.gz")
sha512sums=('607d47e34a134fbcf6a3529eebb569f16d71ec3b7110676450306c27cefe583c132ef164757154e398962cf68a3232bb801afec621a9bddffa584715a94cc117')
prepare() {
chmod +x tuda_latex_templates-${pkgver}/{addlicense,prepare_tuda}.sh
}
build() {
cd tuda_latex_templates-${pkgver}
export TEXINPUTS=".:${srcdir}/tuda_latex_templates-${pkgver}/tex:${TEXINPUTS}"
./addlicense.sh
./prepare_tuda.sh
}
package() {
cd tuda_latex_templates-${pkgver}
install -Dm644 LICENSE_info "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
install -dm755 "${pkgdir}"/usr/share/
cp -r texmf "${pkgdir}"/usr/share/
}
|