blob: 679a6dcac9938f08135c3706330532682896272f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Maintainer: Frederik Schwan <freswa at archlinux dot org>
pkgname=latex-tuda-ci
_pkgname=tuda_latex_templates
pkgver=3.34
pkgrel=1
pkgdesc='TUDa-CI for LaTeX from Technische Universität Darmstadt'
arch=('any')
url='https://github.com/tudace/tuda_latex_templates'
license=('custom')
depends=('latex-tuda-ci-logos')
makedepends=(
'biber'
'texlive-basic'
'texlive-bibtexextra'
'texlive-bin'
'texlive-fontsextra'
'texlive-langcyrillic'
'texlive-langgerman'
'texlive-latexextra'
'texlive-luatex'
'texlive-pictures'
'texlive-publishers'
'zip'
)
replaces=('latex-tuddesign' 'latex-tuddesign-thesis' 'latex-tuddesign-fonts')
source=("https://github.com/tudace/${_pkgname}/archive/v${pkgver}/${pkgver}-${_pkgname}.tar.gz")
b2sums=('3e66c7b4574457b65b68a4450e602210a2bc6c6700b1bf12f2e182627d734f1ad6e8f85fa95f1a59bd2a3d805772c0b78d308096e8e04ee836926eff42858c4b')
prepare() {
chmod +x ${_pkgname}-${pkgver}/{addlicense,prepare_tuda}.sh
}
build() {
cd ${_pkgname}-${pkgver}
export TEXINPUTS=".:${srcdir}/${_pkgname}-${pkgver}/tex:${TEXINPUTS}"
./addlicense.sh
./prepare_tuda.sh
}
package() {
cd ${_pkgname}-${pkgver}
install -Dm644 LICENSE_info "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
install -dm755 "${pkgdir}"/usr/share/
cp -r texmf "${pkgdir}"/usr/share/
}
|