blob: 4f82c3393092523a707a0e6f4fc27ed6ce9afc61 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
|
# Maintainer: Frederik Schwan <freswa at archlinux dot org>
pkgname=latex-tuda-ci
_pkgname=tuda_latex_templates
pkgver=3.27
pkgrel=1
pkgdesc='TUDa-CI for LaTeX from Technische Universität Darmstadt'
arch=('any')
url='https://github.com/tudace/tuda_latex_templates'
license=('custom')
depends=('latex-tuda-ci-logos')
makedepends=('texlive-core' 'texlive-bin' 'texlive-publishers' 'texlive-latexextra' 'texlive-fontsextra'
'texlive-bibtexextra' 'texlive-pictures' 'texlive-langcyrillic' 'biber' 'zip')
replaces=('latex-tuddesign' 'latex-tuddesign-thesis' 'latex-tuddesign-fonts')
source=("https://github.com/tudace/${_pkgname}/archive/v${pkgver}/${pkgver}-${_pkgname}.tar.gz")
b2sums=('da0f0ba927ecc62f455b6a0923cc1586265db3c401b663c63feb5543f5e1ffec82090b17796c0d980d30e5f0f5299193b5e3f886d201cb42ae8975bbd4540307')
prepare() {
chmod +x ${_pkgname}-${pkgver}/{addlicense,prepare_tuda}.sh
}
build() {
cd ${_pkgname}-${pkgver}
export TEXINPUTS=".:${srcdir}/${_pkgname}-${pkgver}/tex:${TEXINPUTS}"
./addlicense.sh
./prepare_tuda.sh
}
package() {
cd ${_pkgname}-${pkgver}
install -Dm644 LICENSE_info "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
install -dm755 "${pkgdir}"/usr/share/
cp -r texmf "${pkgdir}"/usr/share/
}
|