PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60

# Maintainer: doragasu <doragasu (yawn) hotmail (roll) com>
# Contributor: David Manouchehri
#
# Note: If downloads do not work (fail with e.g. error 403), you will have
# to manually download the base package and the latest service pack from
# http://www.latticesemi.com/latticediamond#linux
# Then put these files in the build directory and retry.

_version=3.13
_base=56-2
pkgname=lattice-diamond
pkgdesc='Lattice Diamond design software'
url=http://www.latticesemi.com/
depends=('libusb-compat')
license=('custom')
pkgver=${_version}
pkgrel=2
arch=('x86_64')
install=$pkgname.install
source=("http://files.latticesemi.com/Diamond/${_version}/diamond_${_version/"."/"_"}-base-${_base}-${arch}-linux.rpm"
        "${pkgname}.png"
        "${pkgname}.desktop"
        "${pkgname}.install")
sha512sums=('76b2d77c61a532278470f5dfab7ed409d467f6f5566e56bc9680761c429ad90ac2881b17cac6ef297bc0ddd246ab92403c1a56caa22890b6393e18bb25d7f980'
            '772fa260bb1a4ed7c4e328a99b3cd16b625e8880d7731abbe0cd59dbe4d743265e169a26ceba7b619a87c1cb9638a268a5501d3358863171ee808e59b2d3b0ac'
            'dcfe4d3d4c6892e29456bf898827818dabd02a7ed9f767339bc548ba7dfb9a73e60306484d09ec62693e0899cc1ea2b7ef4550e90dfd8780d505da03fb9cdd3e'
            '0f6f4463e1b1266a151afaaf6fefb3d69b712fafd6f2fa20beb211a3f9dd4db216be7255cc8fddaac946534754739c13406476fc6474236e7505bcd033a71d81')
options=('!strip')
PKGEXT=".pkg.tar.zst"

prepare() {
    # Extract all the packages from base
    for package in bin cae_library data embedded_source examples ispfpga modeltech synpbase tcltk
    do
        echo -en "\tExtracting ${package}..."
        cd ${srcdir}/usr/local/diamond/${_version}/${package}
        tar -xzf ${package}.tar.gz
        rm ${package}.tar.gz
        echo ' done!'
    done

    # Use system libstdc++ to fix Synplify Pro crashes
    cd "${srcdir}/usr/local/diamond/3.13/bin/lin64"
    rm libstdc++.so.6.0.18
    rm libstdc++.so.6
    ln -sf /usr/lib/libstdc++.so.6
    cd "${srcdir}/usr/local/diamond/3.13/synpbase/linux_a_64/lib"
    rm libstdc++.so.6
    ln -sf /usr/lib/libstdc++.so.6
}

package() {
	# Move everything to pkgdir
	mv ${srcdir}/usr ${pkgdir}/
	# Copy .desktop and icon files
	mkdir -p "${pkgdir}/usr/share/pixmaps"
	cp "${srcdir}/lattice-diamond.png" "${pkgdir}/usr/share/pixmaps"
	mkdir -p "${pkgdir}/usr/share/applications"
	cp "$srcdir/lattice-diamond.desktop" "$pkgdir/usr/share/applications/"
}