blob: 5441c07a7d017c4fdeabdd7e1455c63a3b00e49d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Maintainer: Mark Wagie <mark dot wagie at proton dot me>
pkgname=launcher-studio
_app_id=fr.arnaudmichel.launcherstudio
pkgver=0.1.6
pkgrel=1
pkgdesc="A GTK4 desktop application for creating and managing .desktop files"
arch=('x86_64')
url="https://arnaudmichel.fr/projects/launcher-studio"
license=('MIT')
depends=(
'gtk4'
'libadwaita'
)
makedepends=('cargo')
checkdepends=(
'appstream'
'desktop-file-utils'
)
source=("$pkgname-$pkgver.tar.gz::https://github.com/MrArnaudMichel/launcher_studio/archive/refs/tags/v$pkgver.tar.gz")
sha256sums=('c292eb593fbb481a38d67fb08d67aa1107927f3f507ade59ba1707c29296e242')
prepare() {
cd "launcher_studio-$pkgver"
export RUSTUP_TOOLCHAIN=stable
cargo fetch --locked --target host-tuple
}
build() {
cd "launcher_studio-$pkgver"
CFLAGS+=" -ffat-lto-objects"
export RUSTUP_TOOLCHAIN=stable
export CARGO_TARGET_DIR=target
cargo build --frozen --release
}
check() {
cd "launcher_studio-$pkgver"
appstreamcli validate --no-net "data/${_app_id}.metainfo.xml"
desktop-file-validate "data/${_app_id}.desktop"
}
package() {
cd "launcher_studio-$pkgver"
install -Dm755 target/release/launcher_studio -t "$pkgdir/usr/bin/"
install -Dm644 "data/${_app_id}.desktop" -t "$pkgdir/usr/share/applications/"
install -Dm644 "data/${_app_id}.metainfo.xml" -t "$pkgdir/usr/share/metainfo/"
install -Dm644 "assets/icons/${_app_id}.svg" -t \
"$pkgdir/usr/share/icons/hicolor/scalable/apps/"
install -Dm644 assets/icons/"$pkgname"-weather-{night,sunny}-symbolic.svg -t \
"$pkgdir/usr/share/icons/hicolor/symbolic/apps/"
install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
}
|