blob: ebeba056667ee2e887f4646bf5fe00210645b5a7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Maintainer: maronvl <maron.vl@gmx.de>
pkgname=lcd4linux-git
_pkgname=lcd4linux
pkgver=r1167.cb69a93
pkgrel=6
pkgdesc="Grabs information from the kernel and other systems and displays it on an LCD"
arch=('i686' 'x86_64')
url="https://wiki.lcd4linux.tk/doku.php"
license=('GPL-2.0-only')
depends=(
'ncurses' #libncursesw.so
'glibc' #libm.so
'dbus' #libdbus-1.so
'libftdi-compat' #libftdi.so
'libjpeg-turbo' #libjpeg.so
'libusb' #libusb-1.0.so
'libusb-compat' #libusb-0.1.so
'libvncserver' #libvncserver.so
'libx11' #libX11.so
'mariadb-libs' #libmariadb.so
'sqlite' #libsqlite3.so
'gd' #libgd.so
)
makedepends=('git' 'pkg-config' 'automake' 'autoconf')
provides=('lcd4linux')
conflicts=('lcd4linux-svn' 'lcd4linux')
backup=('etc/lcd4linux.conf')
source=('lcd4linux::git+https://github.com/jmccrohan/lcd4linux'
'lcd4linux.service')
md5sums=('SKIP'
'809b7eefb65fd5545e9716dd1b7cf925')
pkgver() {
cd "${_pkgname}"
printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}
prepare() {
cd "${_pkgname}"
export ACLOCAL_PATH="/usr/share/aclocal:/usr/share/gettext/m4${ACLOCAL_PATH:+:}$ACLOCAL_PATH"
export CFLAGS="-std=gnu90"
}
build() {
cd "${_pkgname}"
./bootstrap
./configure --prefix=/usr
make
}
check() {
cd "${_pkgname}"
make -k check
}
package() {
cd "${_pkgname}"
make DESTDIR="${pkgdir}/" install
install -Dm0644 "${srcdir}/lcd4linux.service" "${pkgdir}/usr/lib/systemd/system/lcd4linux.service"
install -Dm0600 "lcd4linux.conf.sample" "${pkgdir}/etc/lcd4linux.conf"
}
|