summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 8e0a50462d244612f0f09e77c7c5e259e518a820 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
# Maintainer: yjun <jerrysteve1101@gmail.com>

pkgname=lceda-bin
_pkgname=${pkgname%-bin}
pkgver=6.3.53
pkgrel=1
pkgdesc="免费、强大、易用的在线电路设计软件"
arch=('x86_64')
url="https://lceda.cn/page/download"
license=('custom')
depends=('gtk3' 'nss' 'libxss')
makedepends=('unzip')
provides=("${_pkgname}")
conflicts=("${_pkgname}")
source=("${_pkgname}-${pkgver}.zip::https://image.lceda.cn/files/${_pkgname}-${pkgver}-linux-x64.zip"
        "LICENSE")
sha256sums=('104aada01fb19dc8a6cfe3913971eb0b78caf6aedf3f56b01015038721c5ba96'
            '686f681d913d7f943bb5aac66cc902f2eb251e7a20fda43412c048d6134b3592')

package() {
  
  install -dm755 ${pkgdir}/opt/${_pkgname}
  unzip -q lceda-linux-x64.zip -d ${pkgdir}/opt/${_pkgname}
  
  # icon
  install -dm755 ${pkgdir}/usr/share/icons/hicolor/
  for icon in 16 32 48 64 128 256;
  do
    install -Dm644 ${pkgdir}/opt/${_pkgname}/icon/${icon}x${icon}/${_pkgname}.png \
    ${pkgdir}/usr/share/icons/hicolor/${icon}x${icon}/apps/${_pkgname}.png
  done
  rm -rf ${pkgdir}/opt/${_pkgname}/icon

  # desktop entry
  install -Dm644 ${pkgdir}/opt/${_pkgname}/LCEDA.dkt ${pkgdir}/usr/share/applications/${_pkgname}.desktop

  sed -i 's|/lceda-linux-x64/icon/128x128/lceda.png|lceda|g' ${pkgdir}/usr/share/applications/${_pkgname}.desktop
  sed -i 's|/lceda-linux-x64/||g' ${pkgdir}/usr/share/applications/${_pkgname}.desktop
  rm -rf ${pkgdir}/opt/${_pkgname}/LCEDA.dkt

  # soft link
  install -dm755 ${pkgdir}/usr/bin
  ln -s /opt/${_pkgname}/${_pkgname} ${pkgdir}/usr/bin/${_pkgname}
  chmod 755 ${pkgdir}/opt/${_pkgname}/${_pkgname}

  # LICENSE
  install -Dm644 LICENSE ${pkgdir}/usr/share/licenses/${pkgname}/LICENSE
}

# vim: set sw=2 ts=2 et: