summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 3028ff6ff5298a6466e8906c03d1d03b7acae056 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>

pkgname=lcms2-git
pkgver=2.9rc1.r12.g66aeefe
pkgrel=1
pkgdesc="Small-footprint color management engine"
arch=('i686' 'x86_64')
url="http://www.littlecms.com/"
license=('MIT')
depends=('glibc' 'libtiff')
makedepends=('git')
provides=('lcms2')
conflicts=('lcms2')
options=('staticlibs')
source=("git+https://github.com/mm2/Little-CMS.git")
sha256sums=('SKIP')


pkgver() {
  cd "Little-CMS"

  git describe --long --tags | sed 's/^lcms//;s/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd "Little-CMS"

  ./autogen.sh
  ./configure --prefix="/usr"
  make
}

check() {
  cd "Little-CMS"

  make check
}

package() {
  cd "Little-CMS"

  make DESTDIR="$pkgdir" install
  install -Dm644 "COPYING" "$pkgdir/usr/share/licenses/lcms2/COPYING"
}