PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43

# Maintainer: Vadim Yanitskiy <fixeria@osmocom.org>
pkgname=lcr-git
pkgver=r558.169afcc
pkgrel=3
pkgdesc="Linux Call Router"
arch=('x86_64' 'i686')
url="http://www.linux-call-router.de/"
license=('GPL')
depends=('sofia-sip' 'opencore-amr')
makedepends=('git' 'autoconf' 'automake' 'make' 'gcc' 'libtool' 'pkg-config')
conflicts=('lcr')
provides=('lcr')
source=("git+https://gitea.osmocom.org/vyanitskiy/lcr.git#branch=fixeria/fixes")
sha256sums=('SKIP')

pkgver() {
  cd "$srcdir/${pkgname%-git}"
  printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
  cd "$srcdir/${pkgname%-git}"
  autoreconf -fi
  ./configure --prefix=/usr \
              --exec-prefix=/usr \
              --bindir=/usr/bin \
              --sbindir=/usr/bin \
              --datadir=/usr/share \
              --libexecdir=/usr/lib \
              --localstatedir=/var \
              --docdir=/usr/share/doc/${pkgname%-git} \
              --libdir=/usr/lib/ \
              --sysconfdir=/etc \
              --with-sip \
              --with-gsm-bs \
              --with-asterisk=no
  make
}

package() {
  cd "$srcdir/${pkgname%-git}"
  make DESTDIR=$pkgdir install
}