blob: 5abd0cca47526eef65ef4dd72a20b6ed21fad506 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer: Serge K <serge.arch@zmail.pro>
# Contributor: Stephen Argent <steve [at] tuxcon [dot] com>
# https://github.com/phnx47/pkgbuilds
_pkgbin=ledger-live-desktop
pkgname=ledger-live-bin
pkgdesc='Ledger Live - Desktop (AppImage version)'
license=('MIT')
url='https://www.ledger.com/ledger-live'
pkgver=2.45.1
pkgrel=1
arch=('x86_64')
depends=('ledger-udev')
options=(!strip)
provides=('ledger-live')
conflicts=('ledger-live' 'ledger-live-git')
_pkgsrc="ledger-live-desktop-${pkgver}-linux-${arch}.AppImage"
source=("${_pkgsrc}::https://download.live.ledger.com/${_pkgsrc}"
"LICENSE::https://raw.githubusercontent.com/LedgerHQ/ledger-live/main/apps/ledger-live-desktop/LICENSE"
)
sha512sums=('e714c0a63b0dedbcecf6217f215e8421bda91d97c47a229f22a4a699377d2091ff8de99c74c29bdae24d5697a7e4dd4d6f33ee2e79ef42c4a62862fe8b2c7ef6'
'915edd51fe7732af57f5a4ca8f4c61c4f435de6357e34ed0733cac8d950d80b3a9e513deac0a3672a07f38ff871a57032a221b3aa27edae8e42cc00586fe3318')
build() {
# Extract files
chmod +x "$srcdir/$_pkgsrc"
$srcdir/$_pkgsrc --appimage-extract
# Correct .desktop
sed -e "s/AppRun/${_pkgbin}/g" -i "$srcdir/squashfs-root/$_pkgbin.desktop"
}
package() {
install -d "$pkgdir/opt/$_pkgbin"
cp -a "$srcdir/squashfs-root/." "$pkgdir/opt/$_pkgbin/"
install -d "$pkgdir/usr/bin"
ln -s "/opt/$_pkgbin/$_pkgbin" "$pkgdir/usr/bin/$_pkgbin"
install -d "$pkgdir/usr/share"
cp -r "$srcdir/squashfs-root/usr/share/." "${pkgdir}/usr/share/"
find "$pkgdir" -type d -exec chmod 755 {} +
install -Dm644 "$srcdir/squashfs-root/$_pkgbin.desktop" "$pkgdir/usr/share/applications/$_pkgbin.desktop"
install -Dm644 "$srcdir/LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}
|