blob: 5875d64d433dcd6fdf8c4089ab382ff5d540740f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
|
# Maintainer: Serge K <arch@phnx47.net>
# For Issues, Pull Requests
# https://github.com/phnx47/pkgbuilds
_appname=ledger-live-desktop
_pkgname=ledger-live
pkgname="${_pkgname}-git"
pkgdesc="Maintain your Ledger devices (git-main)"
_electron='electron28'
pkgver=2.77.2.r0.g264cacb
pkgrel=1
arch=('x86_64')
url='https://github.com/LedgerHQ/ledger-live'
license=('MIT')
depends=('ledger-udev' "${_electron}")
makedepends=('git' 'node-gyp' 'fnm' 'pnpm')
provides=("${_pkgname}")
conflicts=("${_pkgname}")
source=("${pkgname}::git+${url}#branch=main"
"${_appname}.sh")
sha512sums=('SKIP'
'70effe952d7007e79e43523f5e8d868228eedb5049465c2ebea017f9c8b0b25f82e0c6f56cef59e40479d29149969cde8e7098edf8a0cad7b23a9a123e5f0755')
_fnm_use() {
export FNM_DIR="${srcdir}/.fnm"
eval "$(fnm env --shell bash)"
version="$(awk -F "=" '/node/ {print $2}' .prototools | xargs)"
fnm use "${version}" --install-if-missing
}
prepare() {
sed -i "s~@ELECTRON@~${_electron}~" "${_appname}.sh"
}
build() {
cd "${pkgname}"
_fnm_use
pnpm i --filter="ledger-live-desktop..." --filter="ledger-live" --frozen-lockfile --unsafe-perm
pnpm build:lld
# Correct .desktop
sed -e "s/AppRun --no-sandbox/${_appname}/g" -i "apps/${_appname}/dist/__appImage-x64/${_appname}.desktop"
sed -e "/X-AppImage-Version/d" -i "apps/${_appname}/dist/__appImage-x64/${_appname}.desktop"
}
package() {
install -Dm 755 "${_appname}.sh" "${pkgdir}/usr/bin/${_appname}"
cd "${pkgname}/apps/${_appname}"
install -Dm 644 "dist/__appImage-x64/${_appname}.desktop" "${pkgdir}/usr/share/applications/${_appname}.desktop"
install -Dm 755 "dist/linux-unpacked/resources/app.asar" -t "${pkgdir}/usr/lib/${_appname}"
install -Dm 644 "build/icons/icon.png" "${pkgdir}/usr/share/icons/hicolor/64x64/apps/${_appname}.png"
for i in 128 256 512 1024; do
install -Dm 644 "build/icons/icon@${i}x${i}.png" "${pkgdir}/usr/share/icons/hicolor/${i}x${i}/apps/${_appname}.png"
done
install -Dm 644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}
pkgver() {
cd "${pkgname}"
git describe --long --tags --abbrev=7 --match '@ledgerhq/live-desktop@*' | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g' | cut -d@ -f3
}
|