PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50

# Maintainer: Tony Lambiris <tony@criticalstack.com>

pkgname=lemonade-git
pkgver=v1.1.1.r14.gddbd6c1
pkgrel=3
pkgdesc="Lemonade is a remote utility tool. (copy, paste and open browser) over TCP."
url="https://github.com/pocke/lemonade"
arch=('x86_64' 'i686')
license=('MIT')
makedepends=('go')
source=("${pkgname}::git+${url}")
sha256sums=('SKIP')

pkgver() {
	cd "${srcdir}/${pkgname}"

	git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
	cd "${srcdir}/${pkgname}"

	install -m755 -d "${srcdir}/go/src/github.com/pocke/"
	ln -sf "${srcdir}/${pkgname}" "${srcdir}/go/src/github.com/pocke/lemonade"

	cd "${srcdir}/go/src/github.com/pocke/lemonade"

	export GOROOT="/usr/lib/go" GOPATH="${srcdir}/go"
	go get -v -d ./...
}

build() {
	cd "${srcdir}/go/src/github.com/pocke/lemonade"

	mkdir -p build

	export GOROOT="/usr/lib/go" GOPATH="${srcdir}/go"
	go build \
		-ldflags "-s -w -X github.com/lemonade-command/lemonade/lemon.Version=${pkgver}" \
		-gcflags="all=-trimpath=${GOPATH}/src" \
		-asmflags="all=-trimpath=${GOPATH}/src" \
		-o build/lemonade
}

package() {
	cd "${srcdir}/go/src/github.com/pocke/lemonade"

	install -Dm755 "build/lemonade" "${pkgdir}/usr/bin/lemonade"
	install -Dm644 "LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}