blob: 1ff132f257ccd4b0a19119b5f1acf9aa881e87ef (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Maintainer: "Amhairghin" Oscar Garcia Amor (https://ogarcia.me)
# Contributor: David Birks <david@birks.dev>
pkgname=lens
pkgdesc='The Kubernetes IDE'
pkgver=5.3.4
pkgrel=1
arch=('x86_64')
license=('MIT')
url='https://k8slens.dev'
depends=('gtk3' 'libxss' 'nss')
makedepends=('npm' 'nodejs-lts-fermium' 'yarn')
optdepends=('kubectl: Kubernetes control, can be downloaded from settings'
'helm: for Apps section, only useful if your deploy uses helm or plan to use it')
conflicts=('lens-bin')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/lensapp/lens/archive/v${pkgver}.tar.gz"
"${pkgname}.desktop")
b2sums=('9ce9f4597701f9de00af3f680fe11b97e214ef3ca5e4efa7745028a45ee03767817de2eb6b77a5f9a4c6bebf0ec88d69f83f6f965750e6bd526fffccac814d13'
'2aea209098a22d8e4b263a059f6e67b2a3e8f8dfb0c15ac81e33edb4c2be81fd7a6f419a04a77be5b5c8d81b160e6e3f159b4d8639ccab705fffecf149255a36')
build() {
cd "${pkgname}-${pkgver}"
make node_modules
yarn run npm:fix-build-version
make build-extensions
yarn dist:dir
}
package() {
# copy the entire distribution to /usr/share
mkdir -p "${pkgdir}"/usr/share/${pkgname}
mv "${srcdir}"/${pkgname}-${pkgver}/dist/linux-unpacked/* \
"${pkgdir}"/usr/share/${pkgname}
# icon
install -Dm 644 "${srcdir}"/${pkgname}-${pkgver}/build/icons/512x512.png \
"${pkgdir}"/usr/share/icons/hicolor/512x512/apps/open-${pkgname}.png
# desktop file
install -Dm 644 "${srcdir}"/${pkgname}.desktop \
"${pkgdir}"/usr/share/applications/${pkgname}.desktop
# symlink binary
mkdir -p "${pkgdir}"/usr/bin
ln -sf /usr/share/${pkgname}/open-lens \
"${pkgdir}"/usr/bin/open-lens
# symlink helm binary
mkdir -p "${pkgdir}"/usr/share/${pkgname}/resources/helm3
ln -sf /usr/bin/helm \
"${pkgdir}"/usr/share/${pkgname}/resources/helm3/helm3
}
|