blob: 9e374cb3f646e782302f7a39df5db0291e812b95 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Maintainer: "Amhairghin" Oscar Garcia Amor (https://ogarcia.me)
# Contributor: David Birks <david@birks.dev>
pkgname=lens
pkgdesc='The Kubernetes IDE'
pkgver=6.0.0
pkgrel=1
arch=('x86_64')
license=('MIT')
url='https://k8slens.dev'
depends=('gtk3' 'libxss' 'nss')
makedepends=('npm' 'nodejs-lts-gallium' 'yarn')
optdepends=('kubectl: Kubernetes control, can be downloaded from settings'
'helm: for Helm section, only useful if your deploy uses Helm or plan to use it')
conflicts=('lens-bin')
source=("${pkgname}-${pkgver//+/-}.tar.gz::https://github.com/lensapp/lens/archive/v${pkgver//+/-}.tar.gz"
"${pkgname}.desktop")
b2sums=('01696ab8825be10d1bb4171d7187d0fa02daa635a767ed71fda5693bb6612cc5cb6d4031402f6f6b34fc77815ee46fe6932cc1d73c9c288b9684b75e97083683'
'2aea209098a22d8e4b263a059f6e67b2a3e8f8dfb0c15ac81e33edb4c2be81fd7a6f419a04a77be5b5c8d81b160e6e3f159b4d8639ccab705fffecf149255a36')
build() {
cd "${pkgname}-${pkgver//+/-}"
export LANG=C LC_ALL=''
make node_modules
yarn download:binaries
yarn run npm:fix-build-version
make build-extensions
yarn dist:dir
}
package() {
# remove unwanted binaries
rm -f "${srcdir}"/${pkgname}-${pkgver//+/-}/dist/linux-unpacked/resources/x64/{helm,kubectl}
# copy the entire distribution to /usr/share
mkdir -p "${pkgdir}"/usr/share/${pkgname}
mv "${srcdir}"/${pkgname}-${pkgver//+/-}/dist/linux-unpacked/* \
"${pkgdir}"/usr/share/${pkgname}
# icon
install -Dm 644 "${srcdir}"/${pkgname}-${pkgver//+/-}/build/icons/512x512.png \
"${pkgdir}"/usr/share/icons/hicolor/512x512/apps/open-${pkgname}.png
# desktop file
install -Dm 644 "${srcdir}"/${pkgname}.desktop \
"${pkgdir}"/usr/share/applications/${pkgname}.desktop
# symlink binary
mkdir -p "${pkgdir}"/usr/bin
ln -sf /usr/share/${pkgname}/open-lens \
"${pkgdir}"/usr/bin/open-lens
# symlink helm binary
ln -sf /usr/bin/helm \
"${pkgdir}"/usr/share/${pkgname}/resources/x64/helm
}
|