blob: 447c589b0ea851dde71a26ff21b51b819ad78264 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
# Maintainer: "Amhairghin" Oscar Garcia Amor (https://ogarcia.me)
# Contributor: David Birks <david@birks.dev>
pkgname=lens
pkgdesc='The Kubernetes IDE'
pkgver=4.0.5
pkgrel=1
arch=('x86_64')
license=('MIT')
url='https://k8slens.dev'
makedepends=('npm' 'nodejs-lts-erbium' 'yarn')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/lensapp/lens/archive/v${pkgver}.tar.gz"
"${pkgname}.desktop")
sha256sums=('115bedf8908b943b14777c1d210a8b576551e929120d7ef991f24f8024910671'
'3db5b267cededcc73b3e35b89b46fca419e82832b85fa633e4326156cf648d02')
build() {
cd "${pkgname}-${pkgver}"
make -j1 build
}
package() {
# copy the entire distribution to /usr/share
mkdir -p "${pkgdir}"/usr/share/${pkgname}
mv "${srcdir}"/${pkgname}-${pkgver}/dist/linux-unpacked/* \
"${pkgdir}"/usr/share/${pkgname}
# icon
install -Dm 644 "${srcdir}"/${pkgname}-${pkgver}/build/icons/512x512.png \
"${pkgdir}"/usr/share/icons/hicolor/512x512/apps/kontena-${pkgname}.png
# desktop file
install -Dm 644 "${srcdir}"/${pkgname}.desktop \
"${pkgdir}"/usr/share/applications/${pkgname}.desktop
# symlink binary
mkdir -p "${pkgdir}"/usr/bin
ln -sf /usr/share/${pkgname}/kontena-lens \
"${pkgdir}"/usr/bin/kontena-lens
}
|