blob: 310511a90047826f65c319ea89c46944dc07e0d6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Maintainer: "Amhairghin" Oscar Garcia Amor (https://ogarcia.me)
# Maintainer: istimaldar_sntlk <istimaldar@gmail.com>
# Contributor: zer0def <zer0def@github>
_pkgname=lens
pkgname=lens-bin
pkgver=2024.3.271133
pkgrel=1
pkgdesc='The Kubernetes IDE'
arch=('x86_64')
license=('MIT')
url='https://k8slens.dev'
depends=('gtk3' 'libxss' 'nss')
provides=('lens')
conflicts=('lens')
options=('!strip' '!emptydirs')
install="${_pkgname}.install"
source=(${_pkgname}-${pkgver}.${arch}.AppImage::"https://api.k8slens.dev/binaries/Lens-${pkgver}-latest.${arch}.AppImage"
"${_pkgname}.install"
"${_pkgname}.desktop")
b2sums=('0c0d575103e74778d510aef82d4e65fb0944c93c51d28780fa4b8ed95e629c381b8f99babd74f5578fc405ae8c6f9a231c0943766aea9354c162ae4f458ea065'
'824c9dcfd5700335632d814c2c1edc3861e18e5f82f0866474895f7b40d0177097d308d6802944ef1c1b6eda2f58b33647a3b2221e3c482f7cf2085fb97ab6b3'
'7c5afc77c4e921f198139efeb168a16c6208fe0df1267a224ce62bde160d22ec68467f57a560742307ff2bf4e6b5d0bcbf07062b82f1fabcd95e7368d9d02477')
prepare() {
chmod +x "${_pkgname}-${pkgver}.${arch}.AppImage"
"./${_pkgname}-${pkgver}.${arch}.AppImage" --appimage-extract
}
package() {
# move the entire distribution to /usr/share
mkdir -p "${pkgdir}"/usr/share/${_pkgname}
mv "${srcdir}"/squashfs-root/* \
"${pkgdir}"/usr/share/${_pkgname}
# icon
install -Dm 644 "${pkgdir}"/usr/share/${_pkgname}/usr/share/icons/hicolor/512x512/apps/${_pkgname}-desktop.png \
"${pkgdir}"/usr/share/icons/hicolor/512x512/apps/${_pkgname}-desktop.png
# desktop file
install -Dm 644 "${srcdir}"/${_pkgname}.desktop \
"${pkgdir}"/usr/share/applications/${_pkgname}.desktop
# symlink binary
mkdir -p "${pkgdir}"/usr/bin
ln -sf /usr/share/${_pkgname}/lens-desktop \
"${pkgdir}"/usr/bin/lens-desktop
# clean and fix permissions
find "${pkgdir}" -type d -exec chmod 755 {} \;
chmod -x "${pkgdir}"/usr/share/${_pkgname}/*.so
rm -rf "${pkgdir}"/usr/share/${_pkgname}/AppRun
rm -rf "${pkgdir}"/usr/share/${_pkgname}/lens-desktop.{desktop,png}
rm -rf "${pkgdir}"/usr/share/${_pkgname}/usr
rm -rf "${pkgdir}"/usr/share/${_pkgname}/resources/extensions/*/dist/*-arm64
}
|