PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51

# Maintainer: Chocobo1 <chocobo1 AT archlinux DOT net>

pkgname=less-git
pkgver=608.r0.g22e4af5
pkgrel=1
pkgdesc="A free, open-source file pager"
arch=('i686' 'x86_64')
url="https://greenwoodsoftware.com/less/"
license=('custom' 'GPL3')
depends=('glibc' 'ncurses' 'pcre2')
makedepends=('git' 'perl')
provides=("less=$pkgver")
conflicts=('less')
source=("git+https://github.com/gwsw/less.git")
sha256sums=('SKIP')


pkgver() {
  cd "less"

  _tag=$(git tag -l --sort -v:refname | sed '/rc[0-9]*/d' | head -n1)
  _rev=$(git rev-list --count $_tag..HEAD)
  _hash=$(git rev-parse --short HEAD)
  printf "%s.r%s.g%s" "$_tag" "$_rev" "$_hash" | sed 's/^v//'
}

build() {
  cd "less"

  make -f Makefile.aut \
    distfiles \
    all
  ./configure \
    --prefix="/usr" \
    --sysconfdir="/etc" \
    --with-regex=pcre2
  make
}

check() {
  cd "less"

  make check
}

package() {
  cd "less"

  make DESTDIR="$pkgdir" install
  install -Dm644 "LICENSE" -t "$pkgdir/usr/share/licenses/less"
}