blob: 8f47616f4e4f7aa5478f9837b62a89db3b00f836 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# Maintainer: Carlos Aznarán <caznaranl@uni.pe>
# Contributor: Ciappi <marco.scopesi@gmail.com>
pkgname=lfortran
pkgver=0.66.0
pkgrel=1
pkgdesc="Modern interactive LLVM-based Fortran compiler"
arch=(x86_64)
url="https://${pkgname}.org"
license=(BSD-3-Clause)
depends=(clang kokkos zlib ncurses xeus-zmq)
makedepends=(llvm cmake cppzmq zstd libunwind pandoc-cli re2c)
checkdepends=()
optdepends=()
source=(${pkgname}-${pkgver}.tar.gz::https://github.com/${pkgname}/${pkgname}/releases/download/v${pkgver}/${pkgname}-${pkgver}.tar.gz)
sha512sums=('ba9c46c2cad247ddb05eccaf023a607182c48b099d81a59825351fe2b2d5a1a701f9992c22f88e3622798732b47c44f780ee3086d031823d1e8bee64d0b07c0b')
build() {
cmake \
-S ${pkgname}-${pkgver} \
-B build \
-DCMAKE_BUILD_TYPE=Release \
-DCMAKE_INSTALL_PREFIX=/usr \
-DBUILD_SHARED_LIBS=TRUE \
-DCMAKE_CXX_STANDARD=17 \
-DWITH_LLVM=yes \
-DWITH_RUNTIME_LIBRARY=yes \
-DWITH_XEUS=yes \
-DWITH_KOKKOS=yes \
-DWITH_ZLIB=yes \
-DWITH_ZSTD=yes \
-DUSE_DYNAMIC_ZSTD=yes \
-Wno-dev
cmake --build build --target all
}
check() {
ctest --verbose --output-on-failure --test-dir build
}
package() {
DESTDIR="${pkgdir}" cmake --build build --target install
install -Dm 644 ${pkgname}-${pkgver}/LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
}
|