PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33

# Maintainer: Toadtoad <kingdomkeepersguy@gmail.com>
pkgname=lib32-extest
pkgver=1.0.3
pkgrel=1
pkgdesc='X11 XTEST reimplementation primarily for Steam Controller on Wayland '
url='https://github.com/Supreeeme/extest'
source=("$pkgname-$pkgver.tar.gz::https://github.com/Supreeeme/extest/archive/refs/tags/$pkgver.tar.gz"
  "https://raw.githubusercontent.com/Supreeeme/extest/1.0.3/LICENSE")
arch=('x86_64')
license=('MIT')
makedepends=('cargo' 'lib32-rust-libs')
sha256sums=('3b4c63dd0dae72a459b780ce5479eaaa81862cbb902683f62b8c7f1a82ddac73' 'SKIP')

dirname=extest-$pkgver

prepare() {
  cd "$srcdir/$dirname"
  export RUSTUP_TOOLCHAIN=stable
  cargo fetch --locked --target "i686-unknown-linux-gnu" # the package requires this target
}

build () {
  cd "$srcdir/$dirname"
  export RUSTUP_TOOLCHAIN=stable
  export CARGO_TARGET_DIR=target
  cargo build --frozen --release --all-features
}

package() {
  cd "$srcdir/$dirname"
  install -Dm755 target/i686-unknown-linux-gnu/release/libextest.so "${pkgdir}/usr/lib32/libextest.so"
  install -Dm644 "${srcdir}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}