blob: 82f6b84a7be105e9816b4a5ee51eaadaa1e11d4e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Maintainer: Llewelyn Trahaearn <WoefulDerelict at GMail dot com>
# Contributor: xw258
# Contributor: genesis66
pkgname=lib32-fltk
pkgver=1.3.3
pkgrel=6
pkgdesc="Graphical user interface toolkit for X (32-bit)"
arch=('x86_64')
url="http://www.fltk.org"
license=('LGPL')
depends=("${pkgname#lib32-}" 'lib32-gcc-libs' 'lib32-glu' 'lib32-libjpeg-turbo' 'lib32-libpng' 'lib32-libxcursor' 'lib32-libxinerama' 'lib32-libxft')
makedepends=('gcc-multilib')
source=("http://fltk.org/pub/${pkgname#lib32-}/${pkgver}/${pkgname#lib32-}-${pkgver}-source.tar.gz"
"tigervnc.patch" "fltk-config-dynlibs.patch")
sha512sums=('277ba27e35c20e2d4fc5296bf418c5ab78c821870476e21d49f723765b99b3a559eed4ecd5215ac26d53a1091ada003e17f1553194cebaa97dd854809dd2885d'
'30fd8ad3cbedc7e4cb0b3e08d21cc28aa9c8f20d4d1970646de931243c3752f55c4414d921aec29dbdf3b1e4eade0365d3c806fb5c9ecaa29ac3d7cf01f216be'
'33743f009c4486cc2199dc90b031cfe977c779f6bf6e958de29a2180578f3866004f20f6411a049aa1192ea4f8adad4636cd90cb4f0ff6ae05205bd2bc016fef')
prepare() {
cd "${pkgname#lib32-}-${pkgver}"
patch -Np1 -i ${srcdir}/tigervnc.patch
patch -Np1 -i ${srcdir}/fltk-config-dynlibs.patch
sed -i 's/class Fl_XFont_On_Demand/class FL_EXPORT Fl_XFont_On_Demand/' FL/x.H
sed -i -e 's/$(LINKFLTK)/$(LINKSHARED)/' -e 's/$(LINKFLTKIMG)/$(LINKSHARED)/' test/Makefile
}
build() {
# Modify environment to generate 32-bit ELF. Respects flags defined in makepkg.conf
export CC='gcc -m32'
export CXX='g++ -m32'
export LDFLAGS="-m32 ${LDFLAGS}"
export PKG_CONFIG_LIBDIR='/usr/lib32/pkgconfig'
cd "${pkgname#lib32-}-${pkgver}"
./configure \
--build=i686-pc-linux-gnu \
--prefix=/usr \
--libdir=/usr/lib32 \
--libexecdir=/usr/lib32/fltk \
--enable-threads \
--enable-xft \
--enable-shared
make
}
package() {
cd "${pkgname#lib32-}-${pkgver}"
make DESTDIR="${pkgdir}" install
make DESTDIR="${pkgdir}" -C fluid install install-linux
chmod 644 "${pkgdir}"/usr/lib32/*.a
rm -rf "${pkgdir}/usr/"{bin,include,share}
}
|