blob: 6d708fdaeba5938c14394fb430894cd4755e37a7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
|
# Based on lib32-freetype2 from multilib
# Maintainer: Jan Cholasta <grubber at grubber cz>
# Contributor: Ionut Biru <ibiru@archlinux.org>
# Contributor: Jan de Groot <jgc@archlinux.org>
_pkgbasename=freetype2
pkgname=lib32-$_pkgbasename-old-hinting
pkgver=2.8.1
pkgrel=1
pkgdesc="TrueType font rendering library (including the old hinting engine; 32-bit)"
arch=(x86_64)
license=('GPL')
url="https://www.freetype.org/"
# adding harfbuzz for improved OpenType features auto-hinting
# introduces a cycle dep to harfbuzz depending on freetype wanted by upstream
depends=('lib32-zlib' 'lib32-bzip2' 'lib32-libpng' 'lib32-harfbuzz' $_pkgbasename)
makedepends=('gcc-multilib')
provides=('libfreetype.so' "lib32-$_pkgbasename=$pkgver-$pkgrel")
conflicts=("lib32-$_pkgbasename")
source=(https://download.savannah.gnu.org/releases/freetype/freetype-${pkgver}.tar.bz2{,.sig}
0001-Enable-table-validation-modules.patch
0003-Enable-infinality-subpixel-hinting.patch
0004-Enable-long-PCF-family-names.patch)
sha1sums=('417bb3747c4ac95b6f2652024a53fad45581fa1c'
'SKIP'
'c3e91e668936206d3c158bffde0f69788a086a5b'
'81586014ea44375ddc85dd9dbcabae6e91c34d62'
'334f229875039794adeb574e27d365bb445fb314')
validpgpkeys=('58E0C111E39F5408C5D3EC76C1A60EACE707FDA5')
prepare() {
# Rename source dir to allow building the demos
mv freetype-${pkgver} freetype2
cd freetype2
patch -Np1 -i ../0001-Enable-table-validation-modules.patch
patch -Np1 -i ../0003-Enable-infinality-subpixel-hinting.patch
patch -Np1 -i ../0004-Enable-long-PCF-family-names.patch
sed -ri 's|/\* +(#define +CFF_CONFIG_OPTION_OLD_ENGINE) +\*/|\1|' include/freetype/config/ftoption.h
}
build() {
export CC="gcc -m32"
export CXX="g++ -m32"
export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
cd freetype2
./configure --prefix=/usr --disable-static --libdir=/usr/lib32
make
}
check() {
cd freetype2
make -k check
}
package() {
cd freetype2
make DESTDIR="${pkgdir}" install
rm -r "${pkgdir}"/usr/{include,share,bin}
}
|