blob: 2fafd3e48762f6b8b80b7be99648015d70f053ac (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
|
# Maintainer: Joaquín Aramendía <samsagax at gmail dot com>
# Contributor: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: Giancarlo Razzolini <grazzolini@archlinux.org>
# Contributor: Samuel "scrufulufugus" Monson <smonson@irbash.net>
# Contributor: PedroHLC <root@pedrohlc.com>
_pkgname=gamescope
pkgname=lib32-gamescope-plus
pkgver=3.12.2.plus1
pkgrel=1
pkgdesc='SteamOS session compositing window manager with added patches (32-bit)'
arch=(x86_64)
url=https://github.com/ChimeraOS/gamescope
license=(BSD)
conflicts=(lib32-gamescope)
provides=(lib32-gamescope)
depends=(
lib32-wayland
lib32-libx11
lib32-libxcb
lib32-vulkan-icd-loader
)
makedepends=(
benchmark
git
meson
ninja
cmake
vulkan-headers
)
_tag=ef4b761566b4a1c1ec6ea2ec6528af52e674864c
source=("git+https://github.com/ChimeraOS/gamescope.git#commit=${_tag}"
"git+https://gitlab.freedesktop.org/wlroots/wlroots.git"
"git+https://gitlab.freedesktop.org/emersion/libliftoff.git"
"git+https://gitlab.freedesktop.org/emersion/libdisplay-info.git"
"git+https://github.com/Joshua-Ashton/vkroots.git"
"git+https://github.com/nothings/stb.git"
)
b2sums=('SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
'SKIP'
)
prepare() {
cd "$srcdir/$_pkgname"
for src in "${source[@]}"; do
src="${src%%::*}"
src="${src##*/}"
[[ $src = *.patch ]] || continue
echo "Applying patch $src..."
git apply "../$src"
done
git submodule init
git config submodule.subprojects/wlroots.url "$srcdir/wlroots"
git config submodule.subprojects/libliftoff.url "$srcdir/libliftoff"
git config submodule.subprojects/libdisplay-info.url "$srcdir/libdisplay-info"
git config submodule.subprojects/vkroots.url "$srcdir/vkroots"
git -c protocol.file.allow=always submodule update
# make stb.wrap use our local clone
sed -i "s|https://github.com/nothings/stb.git|$srcdir/stb|" "subprojects/stb.wrap"
meson subprojects download
}
pkgver() {
cd gamescope
git describe --tags | sed 's/\-/\./g'
}
build() {
export CC="gcc -m32"
export CXX="g++ -m32"
export PKG_CONFIG="i686-pc-linux-gnu-pkg-config"
export LDFLAGS="$LDFLAGS -lrt"
arch-meson gamescope build \
--libdir=/usr/lib32 \
--buildtype release \
--prefix /usr \
-Denable_gamescope=false \
-Denable_openvr_support=false \
-Dforce_fallback_for=stb,libliftoff,wlroots \
-Dpipewire=disabled \
-Dwlroots:backends=drm,libinput,x11 \
-Dwlroots:renderers=gles2,vulkan
ninja -C build
}
package() {
meson install -C build --skip-subprojects --destdir="${pkgdir}"
install -Dm 644 gamescope/LICENSE -t "${pkgdir}"/usr/share/licenses/lib32-gamescope-plus/
rm -rf "$pkgdir"/usr/include
rm -rf "$pkgdir"/usr/lib/libwlroots*
rm -rf "$pkgdir"/usr/lib32/libwlroots*
rm -rf "$pkgdir"/usr/lib/pkgconfig
rm -rf "$pkgdir"/usr/lib32/pkgconfig
}
# vim: ts=2 sw=2 et:
|