blob: ba144565cbf82cf737683ddabb6492888967a0ee (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Maintainer: Behnam Momeni <sbmomeni [at the] gmail [dot] com>
# Contributor: Daniel Isenmann <daniel@archlinux.org>
pkgname=lib32-gegl
_pkgbase=gegl
pkgver=0.4.26
_commit=3371550915bfe10e9e0add87caaf578464305542 # tags/GEGL_0_4_26
#pkgver=0.4.28
#_commit=811bd306500764a8c64debee4e1e0adda6ac74d3 # tags/GEGL_0_4_28
pkgrel=1
pkgdesc="Graph based image processing framework (32-bit)"
arch=('x86_64')
url="https://www.gegl.org/"
license=('GPL3' 'LGPL3')
depends=("gegl=$pkgver"
'lib32-babl' 'lib32-libspiro' 'lib32-json-glib'
'lib32-poppler-glib'
'lib32-libgexiv2' 'lib32-libraw' 'lib32-openexr'
'lib32-librsvg' 'lib32-libtiff'
'lib32-lensfun' 'lib32-luajit'
'lib32-jasper'
'lib32-suitesparse' 'lib32-ffmpeg')
makedepends=('intltool' 'ruby' 'mesa' 'glu' 'exiv2' 'vala' 'gobject-introspection' 'meson' 'python-gobject')
source=("https://gitlab.gnome.org/GNOME/$_pkgbase/-/archive/$_commit/$_pkgbase-$_commit.tar.gz"
"x86-linux-gnu"
"pkgconf32")
sha512sums=('f488167511d54d2077584fdb38ec09ea77f34172826b2473c140b22d5847648bfc7cefa1423bdf38c0b489be8d658f995df239ae6554486a91a135e4d479c903'
'c90a2e8d8753d4474afbaa5f1def579b4fe9580904b25125e2f942fa722a6ed54340e467d2ddf60ab9d3aeeeb93f5f740502cafe9a1f52d55da3bd78baa3b5c5'
'f704e11f3054312e35974194af845e00fdc795aa97e82d425fb52ff8e628702926551b583f0354f9f9e7eafeb71c7f348c288457ff19a8c4807c58f637d0d946')
prepare() {
cp "/usr/lib/pkgconfig/vapigen.pc" \
"/usr/lib/pkgconfig/gobject-introspection-1.0.pc" \
"/usr/lib/pkgconfig/pygobject-3.0.pc" \
"$srcdir/"
}
build() {
mkdir -p "build"
arch-meson "${_pkgbase}-$_commit" "build" -Dworkshop=true -Dmrg=disabled --cross-file x86-linux-gnu --libdir=/usr/lib32
ninja -C "build"
}
package() {
DESTDIR="$pkgdir" ninja -C "build" install
rm -r "$pkgdir/usr/"{share,include,bin}
}
|