blob: e4b48758e3b621945132160bfe2c294a1eeaf8cf (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# Maintainer: loathingkernel <loathingkernel @at gmail .dot com>
# Contributor: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
pkgname=lib32-gnome-themes-extra
pkgver=3.28+r6+g45b1d457
pkgrel=1
pkgdesc="Extra Themes for GNOME Applications (32-bit)"
url="https://gitlab.gnome.org/GNOME/gnome-themes-extra"
arch=(x86_64)
license=(LGPL2.1)
depends=(cantarell-fonts ${pkgname#lib32-})
makedepends=(intltool lib32-gtk2 lib32-gtk3 git)
optdepends=('lib32-gtk-engines: HighContrast GTK2 theme')
provides=("lib32-gnome-themes-standard=$pkgver")
conflicts=(lib32-gnome-themes-standard)
replaces=('lib32-gnome-themes-standard<3.27.92')
options=('!emptydirs')
_commit=45b1d457c63b1c7f6c8dcb7fe29b23ec7cd63a14 # master
source=("git+https://gitlab.gnome.org/GNOME/gnome-themes-extra.git#commit=$_commit")
sha256sums=('SKIP')
pkgver() {
cd ${pkgname#lib32-}
git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
}
prepare() {
cd ${pkgname#lib32-}
NOCONFIGURE=1 ./autogen.sh
}
build() {
export CC="gcc -m32"
export CXX="g++ -m32"
export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
cd ${pkgname#lib32-}
./configure --prefix=/usr --libdir=/usr/lib32
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
make
}
package() {
cd ${pkgname#lib32-}
make DESTDIR="$pkgdir" install
# remove unneeded stuff
rm -fr ${pkgdir}/{usr/{bin,include,share},etc}
}
# vim:set ts=2 sw=2 et:
|