blob: b5e4283ad3bd3261d2ddeb56acd9a49621bad2dd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
|
# Maintainer: Dan Ziemba <zman0900@gmail.com>
# Contributor: Florian Pritz <bluewind@xinu.at>
# Contributor: Christoph Vigano <mail at cvigano dot de>
# Contributor: Biru Ionut <ionut@archlinux.ro>
# Contributor: Pierre Schmitz <pierre@archlinux.de>
# Contributor: Mikko Seppälä <t-r-a-y@mbnet.fi>
_pkgbasename=gnutls
pkgname=lib32-${_pkgbasename}28
pkgver=3.3.22
pkgrel=1
pkgdesc="A library which provides a secure layer over a reliable transport layer (32-bit, legacy version)"
arch=('x86_64')
license=('GPL3' 'LGPL2.1')
url="http://gnutls.org/"
depends=("${_pkgbasename}28" 'lib32-zlib' 'lib32-nettle' 'lib32-p11-kit'
'lib32-libtasn1')
provides=('lib32-libgnutls28')
conflicts=('lib32-libgnutls28')
makedepends=('gcc-multilib' 'lib32-libidn')
source=(ftp://ftp.gnutls.org/gcrypt/gnutls/v3.3/${_pkgbasename}-${pkgver}.tar.xz{,.sig})
sha256sums=('0ffa233e022e851f3f5f7811ac9223081a0870d5a05a7cf35a9f22e173c7b009'
'SKIP')
validpgpkeys=(1F42418905D8206AA754CCDC29EE58B996865171)
build() {
export CC="gcc -m32"
export CXX="g++ -m32"
export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
cd "${srcdir}/${_pkgbasename}-${pkgver}"
# Guile disabled for conflict with 3.4.x package
# CXX disabled because 3.4.x builds same version libgnutlsxx.so.28.1.0
# openssl, dane, tpm disabled to match 3.4.x package even when building
# outside chroot where those deps are installed
# local libopts enabled to prevent build issue when autogen is installed
# multilib build fails without --disable-hardware-acceleration because of
# assembler errors
./configure --prefix=/usr --libdir=/usr/lib32 \
--includedir=/usr/include/gnutls28 \
--program-suffix=28 \
--with-zlib \
--disable-static \
--disable-guile \
--with-default-trust-store-pkcs11="pkcs11:model=p11-kit-trust;manufacturer=PKCS%2311%20Kit" \
--disable-hardware-acceleration \
--disable-cxx \
--disable-openssl-compatibility \
--enable-local-libopts \
--disable-libdane \
--without-tpm \
--disable-valgrind-tests
make
}
check() {
cd ${srcdir}/${_pkgbasename}-${pkgver}
make -k check
}
package() {
cd "${srcdir}/${_pkgbasename}-${pkgver}"
make DESTDIR="${pkgdir}" install
mv "${pkgdir}"/usr/lib32/pkgconfig/gnutls{,28}.pc
rm -rf "${pkgdir}"/usr/{bin,include,share,lib32/*.so}
}
|