blob: 9b9d2a26622e4b827421427c435a00519e150176 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Maintainer: Ondřej Hošek <ondra.hosek@gmail.com>
# Contributor: Jan de Groot <jgc@archlinux.org>
# Contributor: Maxime de Roucy <maxime.deroucy@gmail.com>
# Contributor: Darwin Bautista <djclue917@gmail.com>
pkgname=lib32-gsm
_pkgbase=gsm
pkgver=1.0.17
pkgrel=1
pkgdesc="Shared libraries for GSM 06.10 lossy speech compression"
arch=('x86_64')
url="http://www.quut.com/gsm/"
license=('custom')
makedepends=('gcc-multilib')
depends=('glibc' 'gsm')
source=("http://www.quut.com/${_pkgbase}/${_pkgbase}-${pkgver}.tar.gz"
'gsm-shared.patch')
sha256sums=('855a57d1694941ddf3c73cb79b8d0b3891e9c9e7870b4981613b734e1ad07601'
'1b9fabd7da83a688fc0e5ec712d53c428ff5575b1d5feac8437283ade1448c2b')
prepare() {
cd "${srcdir}/${_pkgbase}-${pkgver%.*}-pl${pkgver##*.}/"
patch -p0 -i "${srcdir}/gsm-shared.patch"
}
build() {
cd "${srcdir}/${_pkgbase}-${pkgver%.*}-pl${pkgver##*.}/"
# flags for shared lib
CFLAGS="${CFLAGS} -fPIC"
make \
CC="gcc -m32" \
CCFLAGS="-c ${CFLAGS} -fPIC"
}
package() {
cd "${srcdir}/${_pkgbase}-${pkgver%.*}-pl${pkgver##*.}/"
# Prepare directories
install -m755 -d "${pkgdir}"/usr/{bin,lib,lib32,include/gsm,share/{licenses/${_pkgbase},man/man{1,3}}}
make -j1 \
CC="gcc -m32" \
INSTALL_ROOT="${pkgdir}/usr" \
GSM_INSTALL_LIB="${pkgdir}/usr/lib32" \
GSM_INSTALL_INC="${pkgdir}/usr/include/gsm" \
GSM_INSTALL_MAN="${pkgdir}/usr/share/man/man3" \
TOAST_INSTALL_MAN="${pkgdir}/usr/share/man/man1" \
install
# clean directories provided by 64-bit package
rm -Rf "${pkgdir}"/usr/{bin,include,lib,share}
}
|