blob: 0b25a6fa83bbad76a2657dbed3d82ef5975973c8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Maintainer: orumin <dev@orum.in>
_basename=gst-plugins-bad
pkgname="lib32-$_basename"
pkgver=1.8.3
pkgrel=1
pkgdesc="GStreamer Multimedia Framework Bad Plugins (32-bit)"
arch=('x86_64')
license=(LGPL)
url="https://gstreamer.freedesktop.org/"
depends=('mjpegtools' 'lib32-gst-plugins-base-libs' 'curl' 'lib32-chromaprint' 'lib32-libmms'
'lib32-faad2' 'lib32-faac' 'lib32-celt' 'lib32-libdca' 'lib32-soundtouch' 'lib32-spandsp'
'lib32-libdvdnav' 'lib32-libmodplug' 'lib32-libgme' 'lib32-wayland' 'lib32-neon' 'lib32-libofa'
'lib32-fluidsynth' 'lib32-openjpeg' 'lib32-libwebp' 'lib32-libsrtp' 'lib32-gnutls' 'lib32-wildmidi'
'lib32-glu' 'lib32-sbc' 'lib32-rtmpdump' 'lib32-libgudev' 'lib32-graphene' 'gst-plugins-bad')
makedepends=('lib32-schroedinger' 'lib32-libexif' 'lib32-libdvdread' 'lib32-libvdpau' 'lib32-libmpeg2'
'python' 'valgrind-multilib' 'lib32-wildmidi' 'lib32-librsvg' 'gobject-introspection'
'lib32-gtk3' 'lib32-clutter' 'lib32-libtiger' 'lib32-ladspa' 'lib32-openal' 'lib32-libusb'
'vulkan-headers' 'vulkan-icd-loader')
options=(!emptydirs)
source=(${url}/src/$_basename/$_basename-$pkgver.tar.xz)
sha256sums=('7899fcb18e6a1af2888b19c90213af018a57d741c6e72ec56b133bc73ec8509b')
prepare() {
cd $_basename-$pkgver
autoreconf -vi
}
build() {
cd $_basename-$pkgver
export CC='gcc -m32'
export CXX='g++ -m32'
export PKG_CONFIG_PATH='/usr/lib32/pkgconfig'
./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
--build=i686-pc-linux-gnu --libdir=/usr/lib32 \
--disable-qt --disable-teletextdec --disable-x265 --disable-openexr \
--disable-static --enable-experimental --disable-gtk-doc \
--with-package-name="GStreamer Bad Plugins (Arch Linux)" \
--with-package-origin="http://www.archlinux.org/" \
--with-gtk=3.0
# https://bugzilla.gnome.org/show_bug.cgi?id=655517
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
make
}
check() {
cd $_basename-$pkgver
# don't have a camera for the camerabin test
make -k check || :
}
package() {
cd $_basename-$pkgver
make DESTDIR="${pkgdir}" install
cd "$pkgdir"/usr
rm -r include share
}
|