blob: bbc7522380941d6ba0918b14e2743638705d20a9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
|
# Maintainer: Llewelyn Trahaearn <woefulderelict [at] gmail [dot] com>
# Contributor: Peter Lamby <peterlamby [at] web [dot] de>
# Contributor: Stéphane Gaudreault <stephane [at] archlinux [dot] org>
# Contributor: Thomas Dziedzic <gostrc [at] gmail [dot] com>
# Contributor: Denis Martinez <deuns.martinez [at] gmail [dot] com>
pkgname=lib32-intel-tbb
pkgver=2019.9
_tagname=${pkgver/./_U}
pkgrel=1
pkgdesc="High level abstract threading library (32-bit)"
arch=('x86_64')
url="https://threadingbuildingblocks.org"
license=('GPL')
depends=("${pkgname#lib32-}" 'lib32-gcc-libs')
makedepends=('gcc-multilib')
source=("${pkgname#lib32-}-${pkgver}.tar.gz::https://github.com/01org/tbb/archive/$_tagname.tar.gz")
sha256sums=('15652f5328cf00c576f065e5cd3eaf3317422fe82afb67a9bcec0dc065bd2abe')
prepare() {
cd "tbb-${_tagname}"
# Skip debug build. [https://bugs.archlinux.org/task/62757]
sed -i '/debug/d' Makefile
}
build() {
cd "tbb-${_tagname}"
export PKG_CONFIG_LIBDIR='/usr/lib32/pkgconfig'
make arch=ia32
}
package() {
cd "tbb-${_tagname}"
install -d "${pkgdir}/usr/lib32"
install -m755 build/linux_*/*.so* "${pkgdir}/usr/lib32"
}
|