PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45

# Maintainer: Rafael Fontenelle <rafaelff@gnome.org>

_name=ldb
pkgname=lib32-$_name
pkgver=1.1.29
pkgrel=1
pkgdesc="A schema-less, ldap like, API and database"
arch=('i686' 'x86_64')
url="https://ldb.samba.org/"
license=('GPL3')
depends=('lib32-talloc' 'lib32-tevent' 'lib32-tdb' 'lib32-popt' 'ldb')
makedepends=('lib32-python2')
optdepends=('lib32-python2: for python bindings')
source=(https://samba.org/ftp/${_name}/${_name}-${pkgver}.tar.gz)
md5sums=('9c90abfb94c1e2a693399392cf4cddb9')

build() {
	cd "${_name}-${pkgver}"

    # fix python2
    sed -i -e "s|/usr/bin/env python$|/usr/bin/env python2|" buildtools/bin/waf
    
    # set lib32 and python2 environment
    export CC='gcc -m32'
    export CXX='g++ -m32'
    export PKG_CONFIG_PATH='/usr/lib32/pkgconfig'
    export PYTHON='/usr/bin/python2-32'
    export PYTHON_CONFIG='/usr/bin/python2-32-config'
	
	./configure --prefix=/usr \
		--disable-rpath \
		--disable-rpath-install \
		--bundled-libraries=NONE \
		--builtin-libraries=replace \
		--libdir=/usr/lib32 \
        --with-modulesdir=/usr/lib32/ldb/modules \
        --with-privatelibdir=/usr/lib32/ldb
	make
}

package() {
	cd "${_name}-${pkgver}"
	make DESTDIR="${pkgdir}" install
    rm -rf "${pkgdir}"/usr/{bin,include,share}
}