blob: ec7ad681f3a56f69612ab26f4bf8233569779709 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Maintainer: Rafael Fontenelle <rafaelff@gnome.org>
_name=ldb
pkgname=lib32-$_name
pkgver=1.3.2
pkgrel=1
pkgdesc="A schema-less, ldap like, API and database"
arch=('x86_64')
url="https://ldb.samba.org/"
license=('GPL3')
depends=('lib32-talloc' 'lib32-tevent' 'lib32-tdb' 'lib32-popt' 'ldb')
makedepends=('python2' 'lib32-python2' 'lib32-cmocka')
optdepends=('lib32-python2: for python bindings')
source=(https://samba.org/ftp/${_name}/${_name}-${pkgver}.tar.gz)
sha256sums=('ce3ef0b7358a8c5437d2cc0ba3fd6c2f2b7017bc87b09527406c8e34a82376ab')
prepare() {
cd ${_name}-${pkgver}
sed -i -e "s|/usr/bin/env python$|/usr/bin/env python2|" buildtools/bin/waf
}
build() {
cd ${_name}-${pkgver}
export CC='gcc -m32'
export CXX='g++ -m32'
export PKG_CONFIG_PATH='/usr/lib32/pkgconfig'
export PYTHON='/usr/bin/python2-32'
export PYTHON_CONFIG='/usr/bin/python2-32-config'
./configure --prefix=/usr \
--disable-rpath \
--disable-rpath-install \
--bundled-libraries=NONE \
--builtin-libraries=replace \
--libdir=/usr/lib32 \
--with-modulesdir=/usr/lib32/ldb/modules \
--with-privatelibdir=/usr/lib32/ldb
make
}
package() {
cd "${_name}-${pkgver}"
make DESTDIR="${pkgdir}" install
rm -rf "${pkgdir}"/usr/{bin,include,share}
}
|