summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: a05126e25f3055eacf92cf3e42a75afe6dea7743 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
# Maintainer: Andrew Sun <adsun701@gmail.com>

_pkgname=ldns
pkgname=lib32-${_pkgname}
pkgver=1.7.1
pkgrel=1
pkgdesc='Fast DNS library supporting recent RFCs (32-bit)'
url='https://www.nlnetlabs.nl/projects/ldns/'
license=('custom:BSD')
arch=('x86_64')
depends=('lib32-openssl' 'ldns')
makedepends=('lib32-libpcap')
source=("https://www.nlnetlabs.nl/downloads/${_pkgname}/${_pkgname}-${pkgver}.tar.gz")
sha256sums=('8ac84c16bdca60e710eea75782356f3ac3b55680d40e1530d7cea474ac208229')

build() {
  export CC='gcc -m32'
  export CXX='g++ -m32'
  export PKG_CONFIG_PATH='/usr/lib32/pkgconfig'
  
  cd "${srcdir}/${_pkgname}-${pkgver}"
  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc \
    --libdir=/usr/lib32 \
    --localstatedir=/var \
    --disable-rpath \
    --with-drill \
    --without-examples

  make
}

package() {
  cd "${srcdir}/${_pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install
  rm -rf "${pkgdir}"/usr/{bin,include,share}
}