blob: 18bb94ae643dc8f76167e4af5a01a7458cb489db (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Maintainer: Andrew Sun <adsun701@gmail.com>
_pkgname=ldns
pkgname=lib32-${_pkgname}
pkgver=1.7.0
pkgrel=1
pkgdesc='Fast DNS library supporting recent RFCs (32-bit)'
url='https://www.nlnetlabs.nl/projects/ldns/'
license=('custom:BSD')
arch=('x86_64')
depends=('lib32-openssl' 'ldns')
makedepends=('lib32-libpcap')
source=("https://www.nlnetlabs.nl/downloads/${_pkgname}/${_pkgname}-${pkgver}.tar.gz"
'pc.patch')
sha256sums=('c19f5b1b4fb374cfe34f4845ea11b1e0551ddc67803bd6ddd5d2a20f0997a6cc'
'3586302eed28269c7fa6013785c0a017689aa9d4ff24ff8d7735fa23a3732cb7')
prepare() {
cd "${srcdir}/${_pkgname}-${pkgver}"
patch -p1 -i "${srcdir}/pc.patch"
}
build() {
export CC='gcc -m32'
export CXX='g++ -m32'
export PKG_CONFIG_PATH='/usr/lib32/pkgconfig'
cd "${srcdir}/${_pkgname}-${pkgver}"
./configure \
--prefix=/usr \
--sysconfdir=/etc \
--libdir=/usr/lib32 \
--localstatedir=/var \
--disable-rpath \
--with-drill \
--without-examples
make
}
package() {
cd "${srcdir}/${_pkgname}-${pkgver}"
make DESTDIR="${pkgdir}" install
rm -rf "${pkgdir}"/usr/{bin,include,share}
}
|