PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55

# Maintainer: Sefa Eyeoglu <contact@scrumplex.net>
# Contributor: Kazutoshi Noguchi <noguchi.kazutosi+lGlcOenS [at] gmail [dot] com>
# Contributor: Marco Kundt <mrckndt [at] gmail [dot] com>

pkgname=lib32-libgtk3-nocsd-git
pkgver=r55.82ff5a0
pkgrel=6
pkgdesc="A hack to disable gtk+ 3 client side decoration (32-bit library)"
arch=("x86_64")
url="https://github.com/PCMan/gtk3-nocsd"
license=("LGPL")

depends=(
    "gtk3"
    "gtk3-nocsd-git"
)

makedepends=(
    "git"
    "gobject-introspection"
    "gcc-multilib"
    "lib32-glib2"
)

source=(
    "git+https://github.com/PCMan/gtk3-nocsd.git"
)

sha512sums=(
    "SKIP"
)

install="$pkgname.install"

_gitname="gtk3-nocsd"

pkgver() {
    cd "$srcdir/$_gitname"
    printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
}

build() {
    cd "$srcdir/$_gitname"

    export CFLAGS="-m32 ${CFLAGS}"
    export CXXFLAGS="-m32 ${CXXFLAGS}"
    export LDFLAGS="-m32 ${LDFLAGS}"
    export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
    make
}

package() {
    cd "$srcdir/$_gitname"
    install -D -m 0644 libgtk3-nocsd.so.0 "${pkgdir}"/usr/lib32/libgtk3-nocsd.so.0
}