blob: d7071e72d12cbe62fc540f3f00c1c71e383bc861 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# Maintainer: Rodrigo Bezerra <rodrigobezerra21 at gmail dot com>
_basename=libnice
pkgname=lib32-libnice
pkgver=0.1.21
pkgrel=1
pkgdesc="An implementation of the IETF's draft ICE (for p2p UDP data streams) (32-bit)"
url="https://nice.freedesktop.org"
arch=(x86_64)
license=(LGPL)
depends=(lib32-gstreamer lib32-gupnp-igd libnice)
makedepends=(git meson)
_commit=3d9cae16a5094aadb1651572644cb5786a8b4e2d # tags/0.1.21^0
source=("git+https://gitlab.freedesktop.org/libnice/libnice.git#commit=$_commit")
sha256sums=('SKIP')
pkgver() {
cd libnice
git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
}
prepare() {
cd libnice
}
build() {
export CC='gcc -m32'
export CXX='g++ -m32'
export PKG_CONFIG='/usr/bin/i686-pc-linux-gnu-pkg-config'
arch-meson libnice build \
--libdir='/usr/lib32' \
-Dexamples=disabled \
-Dgtk_doc=disabled \
-Dintrospection=disabled
meson compile -C build
}
check() {
meson test -C build --print-errorlogs
}
package() {
DESTDIR="${pkgdir}" meson install -C build
rm -rf "${pkgdir}"/usr/{bin,include}
}
|