summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: c259a56f0e083cf0ed7fbc28c35eead3613ca735 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
# Maintainer: Gicu Gorodenco <cyclopsihus 'at' gmail 'dot' com>
# Contributor: rafael ff1 (aka josephgbr)

_pkgbase=libsigc++
pkgbase=lib32-libsigc++
pkgname=${pkgbase}
pkgver=2.10.3
pkgrel=1
pkgdesc="Callback Framework for C++ (lib32)"
url="https://libsigcplusplus.github.io/libsigcplusplus/"
arch=('x86_64')
license=('LGPL')
depends=(lib32-gcc-libs)
makedepends=(git mm-common meson)
options=('!emptydirs')
_commit=88fdb3a14ec67de233fed22646fc9b14c24367f5  # tags/2.10.3^0
source=("git+https://github.com/libsigcplusplus/libsigcplusplus#commit=$_commit")
sha256sums=('SKIP')

pkgver() {
  cd libsigcplusplus
  git describe --tags | sed 's/-/+/g'
}

prepare() {
  cd libsigcplusplus
}

build() {
  export CC="gcc -m32"
  export CXX="g++ -m32"
  export PKG_CONFIG=/usr/bin/i686-pc-linux-gnu-pkg-config
  export ENABLE_DOCUMENTATION=false

  arch-meson libsigcplusplus build \
    --prefix=/usr \
    --libdir=/usr/lib32 \
    -D maintainer-mode=true \
    -D benchmark=false \
    -D build-examples=false \
    -D build-documentation=false \
    -D build-pdf=false \
    -D validation=false

  ninja -C build
}

check() {
  meson test -C build --print-errorlogs
}

package() {
  provides=("lib32-libsigc++2.0=${pkgver}")
  replaces=('lib32-libsigc++2.0')
  conflicts=('lib32-libsigc++2.0')

  DESTDIR="$pkgdir" meson install -C build


  # Removing files included in base libsigc++ package
  rm -fR ${pkgdir}/usr/include
}