summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 3910acb7fb2dccd53ff282f35e1a26e2b1dbdfd0 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
# Maintainer: Gicu Gorodenco <cyclopsihus 'at' gmail 'dot' com>
# Contributor: rafael ff1 (aka josephgbr)

_pkgbase=libsigc++
pkgbase=lib32-libsigc++
pkgname=${pkgbase}
pkgver=2.10.0
pkgrel=2
arch=('x86_64')
license=('LGPL')
url="http://libsigc.sourceforge.net/"
makedepends=('lib32-gcc-libs' 'git' 'mm-common' 'libxslt' 'graphviz')
options=('!emptydirs')
_commit=83f1e2fe7855f85af570b9653903d2c426d67e72
source=("git://git.gnome.org/libsigcplusplus#commit=$_commit")
sha256sums=('SKIP')

pkgver() {
  cd libsigcplusplus
  git describe --tags | sed 's/-/+/g'
}

prepare() {
  cd libsigcplusplus
  NOCONFIGURE=1 ./autogen.sh
}

build() {
  cd libsigcplusplus
  ./configure --prefix=/usr --libdir=/usr/lib32 CXX='g++ -m32'
  make
}

package() {
  pkgdesc="Libsigc++ implements a full callback system for use in widget libraries - V2"
  depends=('lib32-gcc-libs')

  cd libsigcplusplus
  sed -i -e 's/^doc_subdirs/#doc_subdirs/' Makefile
  make DESTDIR="${pkgdir}" install

  # Removing files included in base libsigc++ package
  rm -rf ${pkgdir}/usr/include
}