summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 6430ceef18fc550a45fb8add133ee3fac5eaec0b (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
pkgname=lib32-libx11-nokeyboardgrab
pkgver=1.6.3
pkgrel=1
pkgdesc='Core X11 protocol client library'
arch=(x86_64)
url=http://www.x.org/wiki/
license=(custom)
depends=(lib32-libxcb libx11)
makedepends=(gcc-multilib inputproto xextproto xtrans)
provides=(lib32-libx11=$pkgver)
conflicts=(lib32-libx11)
source=(${url/wiki\/}releases/individual/lib/libX11-$pkgver.tar.bz2
        ${url/wiki\/}releases/individual/lib/libX11-$pkgver.tar.bz2.sig)
sha256sums=(cf31a7c39f2f52e8ebd0db95640384e63451f9b014eed2bb7f5de03e8adc8111
            SKIP)
validpgpkeys=(4A193C06D35E7C670FA4EF0BA2FB9E081F2D130E)

prepare() {
  cd libX11-$pkgver

  sed -i '/xGrabKeyboardReply/ i \        return (GrabSuccess);' src/GrKeybd.c
}

build() {
  cd libX11-$pkgver

  CFLAGS+=' -m32'

  local confopts=(
    --disable-specs
    --disable-static
    --libdir=/usr/lib32
    --prefix=/usr
  )

  ./configure ${confopts[@]}

  make
}

check() {
  cd libX11-$pkgver

  make check
}

package() {
  cd libX11-$pkgver

  make DESTDIR=$pkgdir install

  rm -r $pkgdir/usr/{include,share}

  install -d $pkgdir/usr/share/licenses/$pkgname
  install -m644 COPYING $pkgdir/usr/share/licenses/$pkgname
}