1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
|
# Maintainer: Lone_Wolf <lonewolf at xs4all dot nl>
# Contributor: Armin K. <krejzi at email dot com>
# Contributor: Kristian Klausen <klausenbusk@hotmail.com>
# Contributor: Egon Ashrafinia <e.ashrafinia@gmail.com>
# Contributor: Tavian Barnes <tavianator@gmail.com>
# Contributor: Jan de Groot <jgc@archlinux.org>
# Contributor: Andreas Radke <andyrtr@archlinux.org>
# Contributor: Thomas Dziedzic < gostrc at gmail >
# Contributor: Antti "Tera" Oja <antti.bofh@gmail.com>
# Contributor: Diego Jose <diegoxter1006@gmail.com>
pkgname=(lib32-mesa-git)
pkgdesc="an open-source implementation of the OpenGL specification, git version"
pkgver=19.2.0_devel.110857.8b3baa27440
pkgrel=1
arch=('x86_64')
makedepends=('python-mako' 'lib32-libxml2' 'lib32-libx11' 'xorgproto'
'lib32-gcc-libs' 'lib32-libvdpau' 'lib32-libelf' 'git' 'lib32-libgcrypt' 'lib32-systemd'
'mesa-git' 'lib32-libglvnd' 'wayland-protocols' 'lib32-wayland' 'meson' 'lib32-libva' 'lib32-libxrandr')
depends=('mesa-git' 'lib32-gcc-libs' 'lib32-libdrm' 'lib32-wayland' 'lib32-libxxf86vm' 'lib32-libxdamage' 'lib32-libxshmfence' 'lib32-elfutils'
'lib32-libunwind' 'lib32-lm_sensors' 'glslang')
optdepends=('opengl-man-pages: for the OpenGL API man pages')
provides=(lib32-mesa=$pkgver-$pkgrel lib32-vulkan-intel=$pkgver-$pkgrel lib32-vulkan-radeon=$pkgver-$pkgrel lib32-libva-mesa-driver=$pkgver-$pkgrel lib32-mesa-vdpau=$pkgver-$pkgrel 'lib32-opengl-driver')
conflicts=('lib32-mesa' 'lib32-vulkan-intel' 'lib32-vulkan-radeon' 'lib32-libva-mesa-driver' 'lib32-mesa-vdpau')
url="https://www.mesa3d.org"
license=('custom')
source=('mesa::git://anongit.freedesktop.org/mesa/mesa'
'LICENSE'
'llvm32.native'
)
md5sums=('SKIP'
'5c65a0fe315dd347e09b1f2826a1df5a'
'6b4a19068a323d7f90a3d3cd315ed1f9')
sha512sums=('SKIP'
'25da77914dded10c1f432ebcbf29941124138824ceecaf1367b3deedafaecabc082d463abcfa3d15abff59f177491472b505bcb5ba0c4a51bb6b93b4721a23c2'
'c7dbb390ebde291c517a854fcbe5166c24e95206f768cc9458ca896b2253aabd6df12a7becf831998721b2d622d0c02afdd8d519e77dea8e1d6807b35f0166fe')
# mesa_which_llvm is an evironment variable used to determine which llvm package tree is used to built mesa-git against
# 1: lone_wolf-llvm-git (aur) Default value
# 2: llvm-git (aur)
# 3 llvm-svn (lordheavy unoffical repo)
# 4 llvm (stable from extra)
#
# N.B. make sure lib32-mesa-git uses same value for this as mesa-git to avoid problems !
if [[ ! $mesa_which_llvm ]] ; then
mesa_which_llvm=1
fi
case $mesa_which_llvm in
1)
# aur lone_wolf-llvm-git
makedepends+=('lone_wolf-lib32-llvm-git')
depends+=('lone_wolf-lib32-llvm-libs-git')
;;
2)
# aur llvm-git
makedepends+=('lib32-llvm-git')
depends+=('lib32-llvm-libs-git')
;;
3)
# mesa-git/llvm-svn (lordheavy unofficial repo)
makedepends+=('lib32-llvm-svn')
depends+=('lib32-llvm-libs-svn')
;;
4)
# extra/llvm
makedepends+=(lib32-llvm=8.0.0)
depends+=(lib32-llvm-libs=8.0.0)
;;
*)
esac
pkgver() {
cd mesa
read -r _ver <VERSION
echo ${_ver/-/_}.$(git rev-list --count HEAD).$(git rev-parse --short HEAD)
}
build () {
export CC="gcc -m32"
export CXX="g++ -m32"
export PKG_CONFIG=/usr/bin/pkg-config-32
if [ -d _build ]; then
rm -rf _build
fi
meson setup mesa _build \
--native-file llvm32.native \
-D b_ndebug=true \
-D buildtype=plain \
--wrap-mode=nofallback \
-D prefix=/usr \
-D sysconfdir=/etc \
--libdir=/usr/lib32 \
-D platforms=x11,wayland,drm,surfaceless \
-D dri-drivers=i915,i965,r200,r100,nouveau \
-D gallium-drivers=r300,r600,radeonsi,nouveau,svga,swrast,virgl,iris \
-D vulkan-drivers=amd,intel \
-D dri3=true \
-D egl=true \
-D gallium-extra-hud=true \
-D vulkan-overlay-layer=true \
-D gallium-nine=true \
-D gallium-omx=disabled \
-D gallium-opencl=disabled \
-D gallium-va=true \
-D gallium-vdpau=true \
-D gallium-xa=true \
-D gallium-xvmc=false \
-D gbm=true \
-D gles1=true \
-D gles2=true \
-D glvnd=true \
-D glx=dri \
-D libunwind=true \
-D llvm=true \
-D lmsensors=true \
-D osmesa=gallium \
-D shared-glapi=true \
-D valgrind=false \
-D tools=[] \
meson configure _build
if [[ ! $NINJAFLAGS ]]; then
ninja -C _build
else
ninja "$NINJAFLAGS" -C _build
fi
}
package() {
DESTDIR="$pkgdir" ninja -C _build install
# remove files provided by mesa-git
rm -rf "$pkgdir"/etc
rm -rf "$pkgdir"/usr/include
rm -rf "$pkgdir"/usr/share/glvnd/
rm -rf "$pkgdir"/usr/share/drirc.d/
rm -rf "$pkgdir"/usr/share/vulkan/explicit_layer.d/
# indirect rendering
ln -s /usr/lib32/libGLX_mesa.so.0 "${pkgdir}/usr/lib32/libGLX_indirect.so.0"
install -Dt "$pkgdir"/usr/share/licenses/$pkgbase/ -m644 "$srcdir"/LICENSE
}
|