blob: a0a97eef324d250c59e2d5e3abe69e0c8cd224d3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
# Maintainer: Kevin Brodsky <corax26 at gmail dot com>
_pkgbasename=ncurses
pkgname=lib32-${_pkgbasename}5-compat-libs
_pkgver=6.0-20170902
pkgver=${_pkgver/-/+}
pkgrel=1
pkgdesc="System V Release 4.0 curses emulation library (32-bit), ABI 5"
arch=('x86_64')
url='http://invisible-island.net/ncurses/ncurses.html'
license=('MIT')
depends=('lib32-glibc' "lib32-${_pkgbasename}")
makedepends=("gcc-multilib")
source=(https://sources.archlinux.org/other/ncurses/ncurses-${_pkgver}.tgz{,.asc})
md5sums=('b7b1cedc484172434855b00831183458'
'SKIP')
validpgpkeys=('C52048C0C0748FEE227D47A2702353E0F7E48EDB') # Thomas Dickey
build() {
cd ${_pkgbasename}-${_pkgver}
export CC="gcc -m32"
export CXX="g++ -m32"
./configure --prefix=/usr --mandir=/usr/share/man \
--with-shared --with-normal --without-debug --without-ada \
--with-install-prefix=${pkgdir} --enable-widec --libdir=/usr/lib32 \
--with-abi-version=5 --without-pkg-config --without-gpm
make
}
package() {
cd ${_pkgbasename}-${_pkgver}
make install.libs
install -dm755 ${pkgdir}/usr/lib32
# fool packages looking to link to non-wide-character ncurses libraries
for lib in ncurses form panel menu; do
ln -s lib${lib}w.so.5 "$pkgdir"/usr/lib32/lib${lib}.so.5
done
# Also provide a libtinfo symlink
ln -s libncurses.so.5 "$pkgdir/usr/lib32/libtinfo.so.5"
# Remove .so symlinks and static libraries (conflicting with lib32-ncurses)
rm -f "${pkgdir}"/usr/{lib32/*.so,lib32/*.a}
rm -rf "${pkgdir}"/usr/{include,share,bin}
mkdir -p "$pkgdir/usr/share/licenses"
ln -s $_pkgbasename "$pkgdir/usr/share/licenses/$pkgname"
}
# vim: set et ts=2 sw=2:
|