blob: dc425bf79ede77b9b3a0a4a48acfb57f69ede011 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
|
# Maintainer: lily wilson <hotaru@thinkindifferent.net>
_pkgbasename=openssl
pkgname=lib32-$_pkgbasename-chacha20
_ver=1.0.2e
# use a pacman compatible version scheme
pkgver=${_ver/[a-z]/.${_ver//[0-9.]/}}
#pkgver=$_ver
pkgrel=1
pkgdesc='The Open Source toolkit for Secure Sockets Layer and Transport Layer Security with ChaCha20 support (32-bit)'
arch=('x86_64')
url='https://www.openssl.org'
license=('custom:BSD')
depends=('lib32-zlib' "${_pkgbasename}")
conflicts=('lib32-openssl')
provides=("lib32-openssl=${pkgver}")
optdepends=('ca-certificates')
makedepends=('gcc-multilib')
options=('!makeflags')
source=("https://www.openssl.org/source/${_pkgbasename}-${_ver}.tar.gz"
"https://www.openssl.org/source/${_pkgbasename}-${_ver}.tar.gz.asc"
'no-rpath.patch'
'ca-dir.patch'
'openssl__chacha20_poly1305_cf.patch')
validpgpkeys=(8657ABB260F056B1E5190839D9C4D26D0E604491)
md5sums=('5262bfa25b60ed9de9f28d5d52d77fc5'
'SKIP'
'dc78d3d06baffc16217519242ce92478'
'3bf51be3a1bbd262be46dc619f92aa90'
'534359a2ce88cd2da618afe509557330')
prepare() {
cd $srcdir/$_pkgbasename-$_ver
# remove rpath: http://bugs.archlinux.org/task/14367
patch -p0 -i $srcdir/no-rpath.patch
# set ca dir to /etc/ssl by default
patch -p0 -i $srcdir/ca-dir.patch
# Cloudflare patch
# https://github.com/cloudflare/sslconfig/blob/master/patches/openssl__chacha20_poly1305_cf.patch
patch -p1 -i $srcdir/openssl__chacha20_poly1305_cf.patch
}
build() {
export CC="gcc -m32"
export CXX="g++ -m32"
export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"
cd $srcdir/$_pkgbasename-$_ver
# mark stack as non-executable: http://bugs.archlinux.org/task/12434
./Configure --prefix=/usr --openssldir=/etc/ssl --libdir=lib32 \
shared zlib \
linux-elf \
"-Wa,--noexecstack ${CPPFLAGS} ${CFLAGS} ${LDFLAGS}"
make MAKEDEPPROG="${CC}" depend
make
}
check() {
cd $srcdir/$_pkgbasename-$_ver
# the test fails due to missing write permissions in /etc/ssl
# revert this patch for make test
patch -p0 -R -i $srcdir/ca-dir.patch
make test
patch -p0 -i $srcdir/ca-dir.patch
}
package() {
cd $srcdir/$_pkgbasename-$_ver
make INSTALL_PREFIX=$pkgdir install_sw
rm -rf ${pkgdir}/{usr/{include,bin},etc}
mkdir -p $pkgdir/usr/share/licenses
ln -s $_pkgbasename $pkgdir/usr/share/licenses/$pkgname
}
|