PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48

# Maintainer: carstene1ns <arch carsten-teibes de> - http://git.io/ctPKG
# Contributor: josephbr <rafael.f.f1@gmail.com>

pkgname=lib32-physfs
pkgver=3.0.1
pkgrel=1
pkgdesc="A library to provide abstract access to various archives (32 bit)"
arch=('x86_64')
url="https://icculus.org/physfs/"
license=('custom: zlib')
depends=('physfs' 'lib32-glibc')
makedepends=('cmake' 'gcc-multilib')
source=("${url}downloads/physfs-$pkgver.tar.bz2")
sha256sums=('b77b9f853168d9636a44f75fca372b363106f52d789d18a2f776397bf117f2f1')

prepare() {
  rm -rf build
  mkdir build
}

build() {
  cd build

  export CC="gcc -m32"
  export CXX="g++ -m32"

  cmake ../physfs-$pkgver \
    -DCMAKE_BUILD_TYPE=Release \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DPHYSFS_BUILD_TEST=OFF \
    -DPHYSFS_BUILD_STATIC=OFF \
    -DLIB_SUFFIX=32
  make
}

package() {
  make -C build DESTDIR="$pkgdir/" install

  # fixup pkg-config file
  sed 's|^libdir.*lib$|&32|' -i "$pkgdir"/usr/lib32/pkgconfig/physfs.pc

  # remove header file
  rm -rf "$pkgdir"/usr/include

  # link license
  install -d "$pkgdir"/usr/share/licenses
  ln -s physfs "$pkgdir"/usr/share/licenses/$pkgname
}