blob: 138766fa0f3992e638ff1c1a71542c811f06f571 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
|
# Maintainer: Vincent Grande <shoober420@gmail.com>
# Contributor: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: Jameson Pugh <imntreal@gmail.com>
# Contributor: J0k3r <moebius282@gmail.com>
pkgname=lib32-sdl2-hg
pkgver=2.0.12
pkgrel=1
pkgdesc="A library for portable low-level access to a video framebuffer, audio output, mouse, and keyboard (Version 2. 32 -bit)"
arch=('x86_64')
url="https://www.libsdl.org"
license=('MIT')
depends=(
lib32-glibc
lib32-libxext
lib32-libxrender
lib32-libx11
lib32-libgl
lib32-libxcursor
lib32-libxxf86vm
sdl2
)
makedepends=(
cmake
jack
lib32-alsa-lib
lib32-mesa
lib32-libpulse
lib32-libxrandr
lib32-libxinerama
lib32-wayland
lib32-libxkbcommon
lib32-libxss
lib32-libxxf86vm
mercurial
wayland-protocols
)
optdepends=(
'lib32-alsa-lib: ALSA audio driver'
'lib32-libpulse: PulseAudio audio driver'
'lib32-jack: JACK audio driver'
)
provides=(lib32-sdl2)
conflicts=(lib32-sdl2 lib32-sdl2-minimal-hg)
source=("hg+https://hg.libsdl.org/SDL#branch=default")
sha512sums=('SKIP')
pkgver() {
#thanks Kozeid
cd "SDL"
printf "%s.r%s.%s" \
"$(hg log -r . -T "{latesttag}" | sed 's/^release-//')" \
"$(hg identify -n)" \
"$(hg identify -i)"
}
prepare() {
#fix libdir
sed -i 's|lib/cmake|lib32/cmake|' SDL/CMakeLists.txt
# Don't try to link against ibus
sed -i '/pkg_search_module.*ibus-1.0/d' SDL/CMakeLists.txt
}
build() {
export CC='gcc -m32'
export CXX='g++ -m32'
export PKG_CONFIG_PATH=/usr/lib32/pkgconfig
cmake -S SDL -B build \
-DCMAKE_INSTALL_PREFIX=/usr \
-DLIB_SUFFIX=32 \
-DSDL_STATIC=OFF \
-DSDL_DLOPEN=ON \
-DARTS=OFF \
-DESD=OFF \
-DNAS=OFF \
-DALSA=ON \
-DPULSEAUDIO_SHARED=ON \
-DVIDEO_WAYLAND=ON \
-DRPATH=OFF \
-DCLOCK_GETTIME=ON \
-DJACK_SHARED=ON
make -C build
}
package() {
make DESTDIR="${pkgdir}" -C build install
rm -rf "${pkgdir}"/usr/{bin,include,share}
sed -i "s/libSDL2\.a/libSDL2main.a/g" "$pkgdir"/usr/lib32/cmake/SDL2/SDL2Targets-noconfig.cmake
install -dm 755 "${pkgdir}"/usr/share/licenses
ln -s sdl2 "${pkgdir}"/usr/share/licenses/lib32-sdl2
ln -s /usr/lib32/libSDL2-2.0.so ${pkgdir}/usr/lib32/libSDL2-2.0.so.0
}
# vim: ts=2 sw=2 et:
|