blob: 5e4727cc75be5a5e851f1d1dff4d33f7aff95203 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
|
# Maintainer: Vincent Grande <shoober420@gmail.com>
# Contributor: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: Jameson Pugh <imntreal@gmail.com>
# Contributor: J0k3r <moebius282@gmail.com>
pkgname=lib32-sdl2-hg
pkgver=2.0.9.r13.45038f8422c9+
pkgrel=2
pkgdesc="A library for portable low-level access to a video framebuffer, audio output, mouse, and keyboard (Version 2. 32 -bit)"
arch=('x86_64')
url="https://www.libsdl.org"
license=('MIT')
depends=('lib32-glibc' 'lib32-libxext' 'lib32-libxrender' 'lib32-libx11' 'lib32-libgl'
'lib32-libxcursor' 'sdl2')
makedepends=('lib32-alsa-lib' 'lib32-mesa' 'lib32-libpulse' 'lib32-libxrandr'
'lib32-libxinerama' 'lib32-wayland' 'lib32-libxkbcommon' 'wayland-protocols'
'lib32-libxss' 'cmake' 'lib32-tslib' 'mercurial')
optdepends=('lib32-alsa-lib: ALSA audio driver'
'lib32-libpulse: PulseAudio audio driver'
'lib32-jack: JACK audio driver'
'jack: JACK audio support')
provides=(lib32-sdl2)
conflicts=(lib32-sdl2)
source=("hg+http://hg.libsdl.org/SDL#branch=default")
sha512sums=('SKIP')
pkgver() {
#thanks Kozeid
cd "SDL"
printf "%s.r%s.%s" \
"$(hg log -r . -T "{latesttag}" | sed 's/^release-//')" \
"$(hg identify -n)" \
"$(hg identify -i)"
}
prepare() {
if [[ -d build ]]; then
rm -rf build
fi
mkdir build
#fix libdir
sed -i 's|lib/cmake|lib32/cmake|' SDL/CMakeLists.txt
# Don't try to link against ibus
sed -i '/pkg_search_module.*ibus-1.0/d' SDL/CMakeLists.txt
}
build() {
cd build
export CC='gcc -m32'
export CXX='g++ -m32'
export PKG_CONFIG_PATH='/usr/lib32/pkgconfig'
cmake ../SDL \
-DCMAKE_INSTALL_PREFIX=/usr \
-DLIB_SUFFIX=32 \
-DSDL_STATIC=OFF \
-DSDL_DLOPEN=ON \
-DARTS=OFF \
-DESD=OFF \
-DNAS=OFF \
-DALSA=ON \
-DPULSEAUDIO_SHARED=ON \
-DVIDEO_WAYLAND=ON \
-DRPATH=OFF \
-DCLOCK_GETTIME=ON \
-DJACK_SHARED=ON
make
}
package() {
make DESTDIR="${pkgdir}" -C build install
rm -rf "${pkgdir}"/usr/{bin,include,share}
sed -i "s/libSDL2\.a/libSDL2main.a/g" "$pkgdir"/usr/lib32/cmake/SDL2/SDL2Targets-noconfig.cmake
install -dm 755 "${pkgdir}"/usr/share/licenses
ln -s sdl2 "${pkgdir}"/usr/share/licenses/lib32-sdl2
}
# vim: ts=2 sw=2 et:
|