blob: a0a72f50e83139c5ebe7782f831c656806850bb1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Maintainer: VitalyR <vr AT vitalyr DOT com>
# Maintainer: HurricanePootis <hurricanepootis@protonmail.com>
# Contributor: Christer Solskogen <christer.solskogen@gmail.com>
pkgname=lib32-sdl3-git
pkgver=3.1.1.r50.g132cef91c
pkgrel=1
pkgdesc="A library for portable low-level access to a video framebuffer, audio output, mouse, and keyboard (Version 3)"
arch=('x86_64' 'i686')
url="https://www.libsdl.org"
license=('Zlib')
depends=('sdl3' 'lib32-glibc' 'lib32-libxext' 'lib32-libxrender' 'lib32-libx11' 'lib32-libgl' 'lib32-libxcursor' 'hidapi' 'lib32-libusb')
makedepends=('lib32-alsa-lib' 'lib32-mesa' 'lib32-libpulse' 'lib32-libxrandr' 'lib32-libxinerama' 'lib32-wayland' 'lib32-libxkbcommon'
'wayland-protocols' 'lib32-libxss' 'cmake' 'lib32-jack' 'ninja' 'lib32-pipewire'
'lib32-libdecor' 'git')
optdepends=('lib32-alsa-lib: ALSA audio driver'
'lib32-libpulse: PulseAudio audio driver'
'lib32-jack: JACK audio driver'
'lib32-pipewire: PipeWire audio driver'
'lib32-libdecor: Wayland client decorations')
source=("git+https://github.com/libsdl-org/SDL.git")
provides=("lib32-sdl3")
conflicts=("lib32-sdl3")
sha512sums=('SKIP')
pkgver() {
cd SDL
git describe --long --tags | sed 's/^release-//;s/\([^-]*-g\)/r\1/;s/-/./g' | sed 's/prerelease.//'
}
build() {
#CFLAGS+=" -ffat-lto-objects"
export CFLAGS+=" -m32"
export CXXFLAGS+=" -m32"
export LDFLAGS+=" -m32"
export PKG_CONFIG_PATH='/usr/lib32/pkgconfig'
cmake -S SDL -B build -G Ninja \
-D SDL_HIDAPI_LIBUSB=ON \
-D CMAKE_INSTALL_PREFIX=/usr \
-D CMAKE_INSTALL_LIBDIR=lib32 \
-D SDL_RPI=OFF \
-D SDL_STATIC=OFF \
-D SDL_RPATH=OFF
cmake --build build
}
package() {
DESTDIR="${pkgdir}" cmake --install build
rm -rf "${pkgdir}/usr/lib/cmake"
rm -rf "${pkgdir}/usr/include"
rm -rf "${pkgdir}/usr/share/man"
mv "${pkgdir}/usr/share/licenses/SDL3" "${pkgdir}/usr/share/licenses/lib32-sdl3-git"
}
|