blob: 6e592dee4e227f56df548ba625ccf065ae1688b3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
# Maintainer: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: Llewelyn Trahaearn <WoefulDerelict@gmail.com>
# Contributor: Claudio Kozicky <claudiokozicky@gmail.com>
# Contributor: Celti <celticmadman@gmail.com>
# Contributor: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
# Contributor: Eric Belanger <eric@archlinux.org>
# Contributor: Jan de Groot <jgc@archlinux.org>
pkgname=lib32-smpeg
pkgver=2.0.0
pkgrel=2
pkgdesc='SDL MPEG Player Library'
arch=(x86_64)
url=https://icculus.org/smpeg/
license=(LGPL)
depends=(
lib32-gcc-libs
lib32-glibc
lib32-sdl2
smpeg
)
makedepends=(
git
lib32-glu
lib32-mesa
)
_tag=62aafbc4ee032c1e9ef02ac8bf98b908c5af62ea
source=(git+https://github.com/icculus/smpeg.git#tag=${_tag})
b2sums=(SKIP)
prepare() {
cd smpeg
./autogen.sh
}
pkgver() {
cd smpeg
git describe --tags | sed 's/^release_//; s/_/./g'
}
build() {
cd smpeg
export CC='gcc -m32'
export CXX='g++ -m32 -std=gnu++03'
export CFLAGS+=' -Wno-format-security -Wno-narrowing'
export PKG_CONFIG=i686-pc-linux-gnu-pkg-config
./configure \
--prefix=/usr \
--libdir=/usr/lib32 \
--disable-static
make
}
package() {
cd smpeg
make DESTDIR="${pkgdir}" install
rm -r "${pkgdir}/usr/"{bin,include,share}
}
# vim: ts=2 sw=2 et:
|