summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 3af1f2c130815744ddc5b4e3eb994d537a6fd279 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
# Maintainer: Nikola Milinković <nikmil@gmail.com>

pkgname=lib32-sni-qt-eplus-bzr
_pkgname=sni-qt-eplus
pkgver=r101
pkgrel=1
epoch=1
pkgdesc='Qt4 plugin which turns all QSystemTrayIcon into StatusNotifierItems. Elementary+ version, from bzr.'
arch=('x86_64')
url='https://launchpad.net/~cybre/+archive/ubuntu/sni-qt-eplus'
license=('LGPL3')
depends=('sni-qt-eplus' 'lib32-libdbusmenu-qt' 'lib32-qt4')
makedepends=('cmake' 'bzr' 'gcc-multilib')
provides=('lib32-sni-qt-eplus' 'lib32-sni-qt')
conflicts=('lib32-sni-qt-eplus' 'lib32-sni-qt')
source=("$_pkgname::bzr+lp:sni-qt"
        'custom-icons-injection.patch')
md5sums=('SKIP'
         'bad3243c40a84a49b77803630b88b89e')

pkgver() {
  cd $_pkgname
  printf "r%s" "$(bzr revno)"
}

prepare() {
  cd "$srcdir"
  mkdir build
  cd "$srcdir"/"$_pkgname"
  patch -p1 -i "$srcdir"/custom-icons-injection.patch
}

build() {
  export CC="gcc -m32"
  export CXX="g++ -m32"
  export PKG_CONFIG_PATH=/usr/lib32/pkgconfig

  export CFLAGS="$(pkg-config --cflags QtCore) ${CFLAGS}"
  export CXXFLAGS="$(pkg-config --cflags QtCore) ${CXXFLAGS}"
  
  cd "$srcdir"/build
  
  cmake ../$_pkgname \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -DCMAKE_BUILD_TYPE=Release \
    -DQT_PLUGINS_DIR=/usr/lib32/qt/plugins
  make
}

package() {
  cd build
  make DESTDIR="${pkgdir}" install
}