PKGBUILD


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51

# Maintainer: Rodrigo Bezerra <rodrigobezerra21 at gmail dot com>

_basename=sratom
pkgname=lib32-sratom
pkgver=0.6.18
pkgrel=1
pkgdesc="An LV2 Atom RDF serialisation library (32-bit)"
arch=(x86_64)
url="https://drobilla.net/software/sratom.html"
license=(ISC)
depends=(
    lib32-glibc
    lib32-lv2
    lib32-serd
    lib32-sord
    sratom
)
makedepends=(meson)
source=("https://download.drobilla.net/$_basename-$pkgver.tar.xz"{,.sig})
sha512sums=('3f78f845974cf7d8a7166e6430a9e8a1454c98b4aea065bd7e66da01dba7a210edc540e17613985ddd8f9124ccf8500b71646942d988f4b9c65dd53f0d18f6cf'
            'SKIP')
b2sums=('f0ac499437b6858d5052ccc4d185c9af7464cec9ddc104da88d7ceda187f7fd17efca4437aeb2b38ec967bfacc6fe2b443be53eda2feb54cb78377a260778c14'
        'SKIP')
validpgpkeys=('907D226E7E13FA337F014A083672782A9BF368F3') # David Robillard <d@drobilla.net>

build() {
    export CC='gcc -m32'
    export CXX='g++ -m32'
    export PKG_CONFIG='/usr/bin/i686-pc-linux-gnu-pkg-config'

    arch-meson $_basename-$pkgver build \
        --libdir='/usr/lib32' \
        -Ddocs=disabled

    meson compile -C build
}

check() {
    meson test -C build
}

package() {
    meson install -C build --destdir "$pkgdir"

    install -vDm 644 $_basename-$pkgver/COPYING -t "$pkgdir/usr/share/licenses/$pkgname/"
    install -vDm 644 $_basename-$pkgver/{NEWS,README.md} -t "$pkgdir/usr/share/doc/$pkgname/"

    cd "$pkgdir/usr"

    rm -r include
}