blob: 55f7aafe03868a412399998d47177aaeda040a88 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
|
# Maintainer: envolution
# Contributor: Behnam Momeni <sbmomeni [at the] gmail [dot] com>
# Contributor: Maxime Gauduin <alucryd@archlinux.org>
# Contributor: Miguel Revilla <yo@miguelrevilla.com>
# Contributor: Eric Bélanger <eric@archlinux.org>
# shellcheck shell=bash disable=SC2034,SC2154
pkgname=lib32-tcl-ar
pkgver=8.6.16
pkgrel=1
pkgdesc='The Tcl scripting language (with *.a files)'
arch=(x86_64)
url=http://tcl.sourceforge.net/
provides=("lib32-tcl=${pkgver}")
conflicts=("lib32-tcl")
license=(custom)
depends=(
lib32-glibc
lib32-zlib
tcl
)
makedepends=(multilib-devel)
options=('staticlibs' '!lto')
source=("https://cfhcable.dl.sourceforge.net/project/tcl/Tcl/${pkgver}/tcl${pkgver}-src.tar.gz")
sha256sums=('91cb8fa61771c63c262efb553059b7c7ad6757afa5857af6265e4b0bdc2a14a5')
prepare() {
cd tcl${pkgver}
rm -rf pkgs/sqlite3*
}
build() {
cd tcl${pkgver}/unix
export CC='gcc -m32'
export CXX='g++ -m32'
export LDFLAGS+=" -lm"
export PKG_CONFIG=i686-pc-linux-gnu-pkg-config
./configure \
--prefix=/usr \
--libdir=/usr/lib32 \
--mandir=/usr/share/man \
--enable-threads
make
}
package() {
cd tcl${pkgver}/unix
make INSTALL_ROOT="${pkgdir}" install install-private-headers
rm -rf "${pkgdir}"/usr/{bin,include,lib,share}
# find "${pkgdir}" -type f -name '*.a' -delete
ln -sf libtcl${pkgver%.*}.so "${pkgdir}"/usr/lib32/libtcl.so
sed -e "s#${srcdir}/tcl${pkgver}/unix#/usr/lib32#" \
-e "s#${srcdir}/tcl${pkgver}#/usr/include#" \
-i "${pkgdir}/usr/lib32/tclConfig.sh"
tdbcver=$(find . -name "tdbcConfig.sh" -exec grep -h -oP "TDBC_VERSION=\K[^']+" {} + | head -n 1)
[[ $tdbcver =~ ^[0-9.]+$ ]] || {
echo "Invalid tdbcver: $tdbcver"
exit 1
}
#tdbcver=1.1.10
sed -e "s#${srcdir}/tcl${pkgver}/unix/pkgs/tdbc${tdbcver}#/usr/lib32/tdbc${tdbcver}#" \
-e "s#${srcdir}/tcl${pkgver}/pkgs/tdbc${tdbcver}/generic#/usr/include#" \
-e "s#${srcdir}/tcl${pkgver}/pkgs/tdbc${tdbcver}/library#/usr/lib32/tcl${pkgver%.*}#" \
-e "s#${srcdir}/tcl${pkgver}/pkgs/tdbc${tdbcver}#/usr/include#" \
-i "${pkgdir}/usr/lib32/tdbc${tdbcver}/tdbcConfig.sh"
itclver=$(find . -name "itclConfig.sh" -exec grep -h -oP "ITCL_VERSION='\K[^']+" {} + | head -n 1)
[[ $itclver =~ ^[0-9.]+$ ]] || {
echo "Invalid itclver: $itclver"
exit 1
}
#itclver=4.3.2
sed -e "s#${srcdir}/tcl${pkgver}/unix/pkgs/itcl${itclver}#/usr/lib32/${itclver}#" \
-e "s#${srcdir}/tcl${pkgver}/pkgs/itcl${itclver}/generic#/usr/include#" \
-e "s#${srcdir}/tcl${pkgver}/pkgs/itcl${itclver}#/usr/include#" \
-i "${pkgdir}/usr/lib32/itcl${itclver}/itclConfig.sh"
install -dm 755 -p "${pkgdir}"/usr/share/licenses
ln -s tcl "${pkgdir}"/usr/share/licenses/lib32-tcl
}
# vim:set ts=2 sw=2 et:
|