summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 02ff863c7c3c5de3671b64d7b7ba23c3d6f8c1b5 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
# Maintainer: orumin <dev at orum.in>

pkgname=lib32-vcdimager
_basename=vcdimager
pkgver=0.7.24
pkgrel=1
pkgdesc="A full-featured mastering suite for authoring disassembling and analyzing Video CD's and Super Video CD's (32-bit)"
arch=('x86_64')
url="http://www.vcdimager.org/"
license=('GPL')
depends=('lib32-libcdio' 'lib32-libxml2' 'lib32-popt' 'vcdimager')
source=(ftp://ftp.gnu.org/gnu/vcdimager/${_basename}-${pkgver}.tar.gz
        vcdimager-0.7.24-libcdio-0.83.patch)
md5sums=('3af22978fd79c79d5fda6513b6811145'
         'f4e7376fd9d975951d2b93a5e9123fdc')

prepare() {
  cd ${_basename}-${pkgver}
  patch -p1 -i "$srcdir/vcdimager-0.7.24-libcdio-0.83.patch"
}

build() {
  cd ${_basename}-${pkgver}

  export CC='gcc -m32'
  export CXX='g++ -m32'
  export PKG_CONFIG_PATH='/usr/lib32/pkgconfig'

  ./configure --prefix=/usr --build=i686-pc-linux-gnu --libdir=/usr/lib32 
  make
}

package() {
  cd ${_basename}-${pkgver}
  make DESTDIR="${pkgdir}" install
  rm -r "${pkgdir}"/usr/bin
  rm -r "${pkgdir}"/usr/include
  rm -r "${pkgdir}"/usr/share
}