summarylogtreecommitdiffstats
path: root/PKGBUILD
blob: 636cee8417529822afb5050ab48d8c455403224f (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
# Maintainer: Gustavo Alvarez <sl1pkn07@gmail.com>

pkgbase="lib32-wxwidgets-light"
pkgname=('lib32-wxbase-light'
         'lib32-wxgtk2-light'
         'lib32-wxgtk3-light'
         'lib32-wxcommon-light'
         )
pkgver=3.0.4
pkgrel=1
pkgdesc="wxWidgets suite for Base and GTK2 and GTK3 toolkits (GNOME/GStreamer free!) (32 bits)"
arch=('x86_64')
url='http://wxwidgets.org'
license=('custom:wxWindows')
makedepends=('lib32-gcc-libs'
             'git'
             'lib32-glu'
             'lib32-gtk2'
             'lib32-gtk3'
             'lib32-libsm'
             'lib32-sdl'
             'lib32-expat'
             'lib32-zlib'
             'lib32-libnotify'
             )
source=("wxwidgets::git+https://github.com/wxWidgets/wxWidgets.git#tag=v${pkgver}"
        'lib32-make-abicheck-non-fatal.patch'
        'lib32-wxwidgets-collision.patch'
        )
sha256sums=('SKIP'
            'd4c2d070a06eb63f0a018c8cf687589e5ffdec601225b4d16a268ffe390fb58b'
            'c73c51f4b65a779462a4e0923a7e3bc7fe28457258fc8bfb5d843d87df119364'
            )

prepare() {
  mkdir -p build-{base,gtk{2,3}}

  cd wxwidgets

  patch -p1 -i "${srcdir}/lib32-wxwidgets-collision.patch"

  # C++ ABI check is too strict and breaks with GCC 5.1
  # https://bugzilla.redhat.com/show_bug.cgi?id=1200611
  patch -p1 -i "${srcdir}/lib32-make-abicheck-non-fatal.patch"
}

build() {
  export CC="gcc -m32"
  export CXX="g++ -m32"
  export PKG_CONFIG_PATH="/usr/lib32/pkgconfig"

  msg2 "Build WxBASE"
  cd "${srcdir}/build-base"
  ../wxwidgets/configure \
      --prefix=/usr \
      --libdir=/usr/lib32 \
      --with-regex=builtin \
      --enable-unicode \
      --disable-{precomp-headers,gui}

  make
  make -C ../wxwidgets/locale allmo

  msg2 "Build WxGTK2"
  cd "${srcdir}/build-gtk2"
  ../wxwidgets/configure \
      --prefix=/usr \
      --libdir=/usr/lib32 \
      --with-gtk=2 \
      --with-lib{jpeg,png,tiff,xpm}=sys \
      --with-regex=builtin \
      --with-{opengl,sdl} \
      --enable-graphics_ctx \
      --without-gnomevfs \
      --disable-{precomp-headers,mediactrl,webview}

  make
  make -C ../wxwidgets/locale allmo

  msg2 "Build WxGTK3"
  cd "${srcdir}/build-gtk3"
  ../wxwidgets/configure \
      --prefix=/usr \
      --libdir=/usr/lib32 \
      --with-gtk=3 \
      --with-lib{jpeg,png,tiff,xpm}=sys \
      --with-regex=builtin \
      --with-{opengl,sdl} \
      --enable-graphics_ctx \
      --without-gnomevfs \
      --disable-{precomp-headers,mediactrl,webview}

  make
  make -C ../wxwidgets/locale allmo
}

package_lib32-wxbase-light() {
  pkgdesc="wxWidgets Base (GNOME/GStreamer free!) (32 bits)"
  depends=('bash'
           'wxbase-light'
           'lib32-gcc-libs'
           'lib32-expat'
           'lib32-zlib'
           )
  provides=('lib32-wxbase')
  conflicts=('lib32-wxbase')
  options=('!emptydirs')

  make -C build-base DESTDIR="${pkgdir}" install

  rm -fr "${pkgdir}/usr/bin/wx-config32"
  mv "${pkgdir}/usr/bin/wx-config32-3.0" "${pkgdir}/usr/bin/wx-config32-3.0-base"
  (cd "${pkgdir}/usr/bin"; ln -s wx-config32-3.0-base wx-config32-base)
  rm -fr "${pkgdir}/usr/include"
  rm -fr "${pkgdir}/usr/share"

  install -Dm644 wxwidgets/docs/licence.txt "${pkgdir}/usr/share/licenses/lib32-wxbase-light/LICENSE"
}

package_lib32-wxgtk2-light() {
  pkgdesc="wxWidgets GTK2 Toolkit (GNOME/GStreamer free!) (32 bits)"
  depends=('wxgtk2-light'
           'lib32-wxbase-light'
           'lib32-gtk2'
           'lib32-libsm'
           'lib32-sdl2'
           'lib32-libnotify'
           )
  provides=('lib32-wxgtk'
            'lib32-wxgtk2'
            )
  conflicts=('lib32-wxgtk'
             'lib32-wxgtk2'
             )
  options=('!emptydirs')

  make -C build-gtk2 DESTDIR="${pkgdir}" install

  cp -P "${pkgdir}/usr/bin/wx-config32" "${pkgdir}/usr/bin/wx-config32-gtk2"
  cp -P "${pkgdir}/usr/bin/wx-config32-3.0" "${pkgdir}/usr/bin/wx-config32-3.0-gtk2"
  rm -fr "${pkgdir}/usr/bin/"wxrc32{,-3.0}
  rm -fr "${pkgdir}/usr/include"
  rm -fr "${pkgdir}/usr/lib32/"*baseu*
  rm -fr "${pkgdir}/usr/share"

  install -Dm644 wxwidgets/docs/licence.txt "${pkgdir}/usr/share/licenses/lib32-wxgtk2-light/LICENSE"
}

package_lib32-wxgtk3-light() {
  pkgdesc="wxWidgets GTK3 Toolkit (GNOME/GStreamer free!) (32 bits)"
  depends=('wxgtk3-light'
           'lib32-wxbase-light'
           'lib32-gtk3'
           'lib32-libsm'
           'lib32-sdl2'
           'lib32-libnotify'
           )
  provides=('lib32-wxgtk3')
  conflicts=('lib32-wxgtk3')
  options=('!emptydirs')

  make -C build-gtk3 DESTDIR="${pkgdir}" install

  rm -fr "${pkgdir}/usr/bin/wx-config32"
  mv "${pkgdir}/usr/bin/wx-config32-3.0" "${pkgdir}/usr/bin/wx-config32-3.0-gtk3"
  (cd "${pkgdir}/usr/bin"; ln -s wx-config32-3.0-gtk3 wx-config32-gtk3)
  rm -fr "${pkgdir}/usr/bin/"wxrc32{,-3.0}
  rm -fr "${pkgdir}/usr/include"
  rm -fr "${pkgdir}/usr/lib32/"*baseu*
  rm -fr "${pkgdir}/usr/share"

  install -Dm644 wxwidgets/docs/licence.txt "${pkgdir}/usr/share/licenses/lib32-wxgtk3-light/LICENSE"
}

package_lib32-wxcommon-light() {
  pkgdesc="wxWidgets common (GNOME/GStreamer free!) (32 bits)"
  depends=('wxcommon-light'
           'lib32-wxbase-light'
           )
  provides=('lib32-wxcommon'
            'lib32-wxgtk-common'
            )
  conflicts=('lib32-wxcommon'
             'lib32-wxgtk-common'
            )
  options=('!emptydirs')

  make -C build-gtk2 DESTDIR="${pkgdir}" install
  rm -fr "${pkgdir}/usr/bin"
  make -C build-gtk3 DESTDIR="${pkgdir}" install
  rm -fr "${pkgdir}/usr/bin/"wx-config32{,-3.0}
  make -C build-base DESTDIR="${pkgdir}" install

  rm -fr "${pkgdir}/usr/bin/"wx-config32{,-3.0}
  rm -fr "${pkgdir}/usr/include"
  rm -fr "${pkgdir}/usr/lib32"
  rm -fr "${pkgdir}/usr/share"

  install -Dm644 wxwidgets/docs/licence.txt "${pkgdir}/usr/share/licenses/lib32-wxcommon-light/LICENSE"
}